为什么这个函数的 pointfree 版本看起来像这样？

Question

我一直在使用 Haskell，包括练习以无点形式编写函数。这是一个示例函数：

dotProduct :: (Num a) => [a] -> [a] -> a
dotProduct xs ys = sum (zipWith (*) xs ys)

我想以无点形式编写这个函数。这是我在其他地方找到的一个例子：

dotProduct = (sum .) . zipWith (*)

但是，我不明白为什么无点形式看起来像 (sum .) 。 zipWith (*) 而不是 sum 。 zipWith (*).为什么 sum 放在括号中并且有 2 个复合运算符？

Answer 1

KennyTM 的答案非常好，但我仍然想提供另一种观点：

dotProduct = (.) (.) (.) sum (zipWith (*))

• (.) f g 在给定的 g 的结果上应用 f参数
• (.) (.) (.) f g 将 f 应用于给定两个参数 (.) (.) g 的结果
• 。 ) ((.) (.) (.)) f g 在给定三个参数的 g 的结果上应用 f
• ...
• 可以做 ( .~) = (.) (.) (.), (.~~) = (.) (.) (.~), (.~~~ ) = (.) (.) (.~~) 现在 let foo abcd = [1..5]; (.~~~) sum foo 0 0 0 0 结果为 15。
  • 但我不会这么做。它可能会使代码不可读。只要满分就好。
• Conal 的 TypeCompose 提供了 (.) 的同义词，称为 result。也许这个名字更有助于理解正在发生的事情。
  如果导入相关实例（import Control.Applicative 就可以），
  • fmap 也可以代替 (.)，但它的类型更笼统，因此可能更令人困惑。
• Conal 的“融合”概念（不要与“融合”的其他用法混淆）是相关的，恕我直言，它提供了一种很好的组合函数的方法。更多详细信息，请参阅 Conal 发表的这篇长篇 Google 技术讲座

Answer 2

dotProduct xs ys = sum (zipWith (*) xs ys)             -- # definition

dotProduct xs    = \ys -> sum (zipWith (*) xs ys)      -- # f x = g <=> f = \x -> g
                 = \ys -> (sum . (zipWith (*) xs)) ys  -- # f (g x) == (f . g) x
                 = sum . (zipWith (*) xs)              -- # \x -> f x == f
                 = sum . zipWith (*) xs                -- # Precedence rule

dotProduct       = \xs -> sum . zipWith (*) xs         -- # f x = g <=> f = \x -> g
                 = \xs -> (sum .) (zipWith (*) xs)     -- # f * g == (f *) g
                 = \xs -> ((sum .) . zipWith (*)) xs   -- # f (g x) == (f . g) x
                 = (sum .) . zipWith (*)               -- # \x -> f x == f

---

(sum .) 是一个部分。它被定义为

(sum .) f = sum . f

任何二元运算符都可以这样写，例如map (7 -) [1,2,3] == [7-1, 7-2, 7-3]。