在 Mathematica 中的 Hold 中评估超过一级

Question

关于 Evaluate at possible issues 的 mathematica 文档说：

仅评估第一个作品 级别，直接在持有的函数内

为什么 Mathematica 有这个限制？因此，如果我有一个以上级别的表达式，请采用以下简化示例：

Hold[Plus[Plus[2, 2], 2]]]

现在假设我想看看第二个 Plus 的答案是什么，而不评估任何内容在低于它的水平上。我尝试过不同的事情，例如：

In[290]:= Hold[Plus[Evaluate[Plus[2, 2]], 2]]
Out[290]= Hold[Evaluate[2+2]+2]

In[287]:= Hold[Plus[ReleaseHold[Hold[Plus[2, 2]]], 2]]
Out[287]= Hold[ReleaseHold[Hold[2+2]]+2]

在这种情况下，第一个保留使所有内容在第一级和第一级之后都未被评估。 目标是使用连续的 Hold、ReleaseHold 和 Evaluate 函数来控制从最内层嵌套函数到外层嵌套函数的每个阶段的表达式计算。我知道我可以使用跟踪来查看表达式中第一级之后发生的情况，但这是不同的，有时用较长的表达式来读取会很复杂。

似乎唯一的方法是使用 Extract、Part 或 Level 将表达式提取并完全分解为列表；评估我想要的表达式的一部分；然后为每个阶段重建并重新映射表达式。我可以考虑其他方法或功能来实现这一目标吗？

编辑：这可能是一个更好的例子来了解释放第一个保持的方法。使用表达式：

Hold[Plus[Plus[2, Plus[2,2]], 2]]]

如果您释放第一个保留并在第三个 Plus 处的表达式中将保留置于较高级别上，则如下所示：

in = Plus[Plus[2, Hold[Plus[2,2]]], 2]]]
out = Hold[2+2]+4

您会发现，当您确实希望 Mathematica 等待时，它会在后台计算较低级别。

Answer 1

我无法给出 Evaluate “仅在第一级工作，直接在保留函数内工作”的确切原因，但我怀疑这部分是效率问题，因为如果评估器必须扫描，它会很慢传递给具有嵌套 Evaluate 表达式的 Hold* 属性的任何函数的完整表达式树，并对它们进行求值，然后递归并查找 Evaluate 子表达式在它刚刚计算的内容中，同时保持表达式的其余部分不计算，特别是当这可能并不总是您想要发生的情况时。

不过，使用 Extract 和 ReplacePart 的组合来完成您想要的操作非常容易：

In[51]:= expr = Hold[Plus[Plus[2, 2], 2]];

In[52]:= ReleaseHoldAt[expr_, partspec_] :=
  ReplacePart[expr, partspec -> Extract[expr, partspec]]

In[53]:= ReleaseHoldAt[expr, {1, 1}]

Out[53]= Hold[4 + 2]

这让我们说明了为什么它对于 Evaluate 可能没有意义的另一个原因> 在作为参数传递给具有 Hold* 属性的函数的表达式中的任何级别上工作，考虑到以下涉及 i 的表达式：

In[82]:= i = 1;

In[83]:= ReleaseHoldAt[Hold[i = 2; j = Plus[i, i]], {1, 2}]

Out[83]= Hold[i = 2; 2]

请注意 的值如果我们在 Plus 之前计算该表达式的第一部分，>j 将会是 4，但结果会有所不同，因为我们只进行部分计算，并且当我们计算子表达式设置 j 时，尚未计算 i=2。有时，这可能是您希望发生的事情，但通常情况下它很可能不是。

请记住，即使第一级中的 Evaluate 也可能被具有 HoldAllComplete 属性的函数或使用 HoldComplete 击败：

In[62]:= Hold[Evaluate[Plus[2,2]]]
Out[62]= Hold[4]

...与：

In[63]:= HoldComplete[Evaluate[Plus[2,2]]]
Out[63]= HoldComplete[Evaluate[2+2]]

最后，Trace 的输出可能有点密集，但是您可以通过在第二个参数中使用感兴趣的模式或符号来过滤掉您想要的内容：

In[88]:= Trace[Plus[Plus[Plus[1,2],3],4],Plus]
Out[88]= {{{1+2,3},3+3,6},6+4,10}

In[93]:= Trace[Plus[Subtract[Plus[1,2],4],8],_Plus]
Out[93]= {{{1+2}},-1+8}

HTH！

Answer 2

当您想在 Mathematica 中做一些棘手的事情时，通常会出现这种情况，模式匹配和规则替换可以帮助您。然而，在这种情况下，你必须做一些奇怪的事情，并且您必须使用 Replace 而不是 ReplaceAll （/. 运算符），以便您可以利用其可选的第三个参数给它一个级别规范。使用您提供的示例：

In[1]:= Replace[
         Hold[Plus[Plus[2, 2], 2]],
         expr_Plus :> With[{eval = expr}, eval /; True],
         {2}]
Out[1]= Hold[4 + 2]

看似无用的

expr_Plus :> With[{eval = expr}, eval /; True]

规则实际上是一种记录方式在测试匹配和 With 结构体之间共享局部变量；在这里，您不对局部变量执行任何操作，而是以迂回方式强制对其求值——因为较少的迂回方式是行不通的！

编辑添加：我认为您误解了Level的结果；该表达式的 {2} 级别的两个表达式是 2 和 Plus[2, 2]；您可以通过使用 level 的可选第三个参数来看到这一点，它的作用类似于 Extract 的可选第三个参数：

In[2]:= Level[Hold[Plus[Plus[2, 2], 2]], {2}, Hold]
Out[2]= Hold[2 + 2, 2]

使用 {2} 级别规范，Replace 将尝试根据这两个表达式匹配并替换规则，并且它将对第二个表达式起作用。

Answer 3

不涉及 Extract 的技术是将 Hold 内的部分包装在内部 Hold 中，然后释放外部 Hold< /code>：

expr=Hold[(1+2)+3];
ReleaseHold@Map[Hold,expr,{2}]

Out[2]= Hold[3]+Hold[1+2]

你可以朝这个方向玩各种游戏，但由于我无法说出你想做什么，所以有点难以具体。可能有用的方法是定义您自己的 Hold，它会按照您想要的方式下降：

SetAttributes[DescentHold,{HoldAll}]
DescentHold[a_Plus]:=ReleaseHold@Map[DescentHold,Hold[a],{2}]
DescentHold[a_]:=Hold[a]

请注意，一旦内部被包裹，这个就会接近外部 Hold，因此例如 Plus 的平坦度开始发挥作用：

DescentHold[2*3+(4+5)]
Out[4]= Hold[4]+Hold[5]+Hold[2*3]

Answer 4

使用 答案，作者：Michael Pilat，可以写HoldAndEvaluate 函数，该函数允许他计算表达式中所需的部分，而无需计算其位置（可以用“MyEvaluate”标记）。

In[1]:= expr = Hold[MyEvaluate[2 + 2] + 2];

In[2]:= HoldAndEvaluate[expr_] :=
  ReplacePart[expr,
    # -> Evaluate @@ Extract[expr, #] & /@ 
    Position[expr, MyEvaluate[_]] ];

In[3]:= HoldAndEvaluate[expr]

Out[3]= Hold[4 + 2]