如何在 Mathematica 中使用函数式编程减去列表中的特定元素？

Question

我有一个格式为以下的日期和值列表：

{{{dateInfo1},value1},{{dateInfo2},value2},...,{{dateInfoN},valueN}}

一些实际的日期和值：

{{{1971, 1, 31, 0, 0, 0.}, 1.0118}, {{1971, 2, 28, 0, 0, 0}, 1.0075},
 ..., {{2010, 5, 31, 0, 0, 0.}, 1.0403}}

对于那些好奇的人来说，这是从 FRED 数据库。

我想简单地从值 2 中减去 value1，然后创建一个新列表，其数据格式如下：

 {{{dateInfo1},0},{{dateInfo2},change1},...,{{dateInfoN},changeN-1}}

（change1 为 value2-value1）

我知道一定有一种相对简单的方法可以使用函数式编程来完成此操作，而不是使用索引变量和计数以及所有这些废话来执行此操作。我试图实现的方法必须相对稳健，因为我会自动从具有相同格式但不同时间间隔的源中提取数据集。如果我不必指定 ListPlot 日期间隔（如果我从列表中删除 dateInfo 就会发生这种情况），那么重新绘制就会容易得多。

我熟悉文档中心和 Mathematica 非编程功能。我一直在使用 Mathematica 学习编程，并且真的想将这种能力扩展到函数式编程，但发现有关该主题的大多数资源都有点太困难了。我觉得我正处于学习曲线的驼峰上，即将步入正轨，但现在我正在挣扎。至少，如果您有关于函数式编程的良好资源，我会非常乐意研究这些！非常感谢任何帮助！抱歉，如果是 TMI，但我相信你们很多人也有同样的感觉。

Answer 1

您有一个 {date,value} 对列表，因此如果您转置您将得到一个包含两个列表的列表 - 第一个是日期列表，第二个是相应值的列表。
然后，您可以获取值的差异，前置 0，然后再次转置以返回对列表。

在代码中，

data = {{{1971,1,31,0,0,0}, 1.0118}, 
        {{1971,2,28,0,0,0}, 1.0075}, 
        {{2010,5,31,0,0,0}, 1.0403}}
{dates, values} = Transpose[data];
diffs = Prepend[Differences[values], 0];
answer = Transpose[{dates, diffs}]

返回：

{{{1971,1,31,0,0,0}, 0}, 
 {{1971,2,28,0,0,0}, -0.0043}, 
 {{2010,5,31,0,0,0}, 0.0328}}

将其包装到单个函数中，感谢 Janus 的想法：

taildiffs[data_]:= 
  Transpose @ {#1, Prepend[Differences[#2], 0]}& @@ Transpose@data  

请注意... #1 ... #2 ... & 构造是一个纯函数：

http://reference.wolfram.com/mathematica/ref/Function.html

f@x 语法只是 f[ 的简写形式x]。

最后，f@@list 是 Apply[f, list] 的简写：

http://reference.wolfram.com/mathematica/ref/Apply.html

所以上面定义的 taildiffs 只是这个的简洁（也许是神秘的）版本：

Apply[Transpose[Function[{x,y}, {x, Prepend[Differences[y],0]}], Transpose[data]]

Answer 2

除了您想要初始的 0 之外，您还要寻找差异。要保留日期，请转置并仅应用于第二部分，如下所示：

TailDifferences[data_]:=
  Transpose@Apply[{#1,{0}~Join~Differences[#2]}&,Transpose[data]]

将其应用于数据会产生如下所示的结果：

data={{{dateInfo1},value1},{{dateInfo2},value2},{{dateInfo3},value3}};
TailDifferences[data]

{{{dateInfo1},0},{{dateInfo2},-value1+value2},{{dateInfo3},-value2+value3}}

Answer 3

我建议使用 Reap 和 Sow 为此：

In[13]:= lis= {{{1971,1,31,0,0,0.},1.0118},{{1971,2,28,0,0,0},1.0075},{{2010,5,31,0,0,0.},1.0403}};

In[14]:= First@Last@Reap[
   (* set first previous to first value to get 0 *)
   Module[{prev = lis[[1, 2]]},
    Scan[
     (
       (* First[#] = date, Last[#] = value *)
       Sow[{First[#], Last[#] - prev}];
       (* set new previous to this value *)
       prev = Last[#]
       ) &,
     lis]]
   ]

Out[14]= {{{1971, 1, 31, 0, 0, 0.}, 0.},
  {{1971, 2, 28, 0, 0, 0}, -0.0043},
  {{2010, 5, 31, 0, 0, 0.}, 0.0328}}

Reap 会有点复杂，但是 Reap 和 Sow 基本上为您提供了一种将事物“播种”到列表中然后“收获”的方法评估后的他们。例如，Reap 和 Sow 比使用 AppendTo 和列表要高效得多。

哈！

Answer 4

data = {{{dateInfo1}, value1}, {{dateInfo2}, value2}, {{dateInfo3}, value3}}

Map[{#[[2,1]], #[[2,2]] - #[[1,2]]}&, {Take[data, Length[data] - 1], Rest[data]}]

结果

{{{dateInfo2}, -value1 + value2}, {{dateInfo3}, -value2 + value3}}

列表中的第一个元素

{{dateInfo1},0}

并不真正适合序列，因此您可以手动将其添加到列表中

Answer 5

此操作也可以使用 Part 和 Set 完成：

data = {{{1971,1,31,0,0,0}, 1.0118}, 
        {{1971,2,28,0,0,0}, 1.0075}, 
        {{2010,5,31,0,0,0}, 1.0403}};

Module[{a = data},
  a[[2 ;;, 2]] = Differences[a[[All, 2]]];
  a[[1, 2]] = 0;
  a
]

{{{1971, 1, 31, 0, 0, 0}, 0},
 {{1971, 2, 28, 0, 0, 0}, -0.0043},
 {{2010, 5, 31, 0, 0, 0}, 0.0328}}