无法解析由分隔符分隔的字符串（包含路径）

Question

我在解析仅包含目录路径的字符串时遇到问题。例如，

我的输入字符串是 Abc\Program Files\sample\

我的输出应该是 Abc//Program Files//sample

该脚本应该适用于任何输入路径长度，即它可以包含任何编号。子目录。 （例如，abc\temp\sample\folder\joe）

我在许多链接中寻求帮助但无济于事。看起来 FOR 命令只提取一整行或一个字符串（当我们在 FOR 语法中使用“token”关键字时），但我的问题是我不知道输入路径长度，因此，没有。的代币。

我的想法是使用 \ 作为分隔符，然后提取它 () 之前和之后的每个单词，并将这些单词与 // 一起放入输出文件，直到到达字符串末尾。

我尝试实现以下内容，但它不起作用：

@echo off

FOR /F "delims=\" %%x in (orig.txt) do (
    IF NOT %%x == "" echo.%%x//>output.txt    
)

文件 orig.txt 仅包含一行，即 Abc\Program Files\sample\

我得到的输出仅包含： Abc//

上面的输出在 ' 之后也包含空格Abc//'

我想要的输出应该是： Abc//program Files//sample//

谁能帮我解决这个问题？

问候，
科技下一步

Answer 1

你尝试过模式匹配吗？我知道在perl和Java中你可以做一个简单的替换，找到所有的“\”并将它们替换为“//”

perl中的示例：

my $var = "Abc\Program Files\sample\"
$var  =~ tr/\\/\/\//; 

只需查找模式匹配或正则表达式

Answer 2

您可以使用简单的字符串替换：

C:\>set myvariable=Abc\Program Files\sample\    

C:\>echo %myvariable%
Abc\Program Files\sample\

C:\>set myvariable=%myvariable:\=//%

C:\>echo %myvariable%    
Abc//Program Files//sample//

Answer 3

使用循环和临时文件，以下内容适用于您的场景：

@echo off > output.txt
FOR /F "tokens=1,* delims=\" %%x in (orig.txt) do ( 
IF NOT %%y=="" echo %%x//%%y>>output.txt
)
:loop
@echo off > temp.txt
set /a stop=1
FOR /F "tokens=1,* delims=\" %%x in (output.txt) do (
IF NOT "%%y"=="" (
echo %%x//%%y>>temp.txt
set /a stop=0
) ELSE (echo %%x>>temp.txt)
)
IF NOT %stop%==1 (
move /Y temp.txt output.txt
) ELSE (goto end)
goto loop
:end
move /Y temp.txt output.txt

给定此输入，

Abc\Program Files\sample\
Another\Example\\\

您将得到以下输出：

Abc//Program Files//sample
Another//Example

非常丑陋，不是吗？ ^^

Answer 4

感谢您的投入凯拉！我知道这在 Shell 或 Perl 中很容易，但无论如何，我现在已经找到了解决方案。

这是：

---

type nul>output.txt

FOR /F "usebackq tokens=*" %%x in ("orig.txt") do (
    set LINE=%%x
    call set LINE=%%LINE:\=//%%
    call echo:%%LINE%%
) >>output.txt

---

谢谢hoang。我正想发帖就看到你的回复了。