了解表 API 和事务 API 之间的差异

Question

朋友们，

请询问 Tom 线程 我通过另一个SO问题发现的，提到了表和事务API，我试图理解它们之间的区别。

表 API (TAPI) 是无法访问底层表并且存在“getter”和“getter”的地方。 “设置者”获取信息。

例如，要选择一个地址，我会：

   the_address := get_address(address_id);

而不是：

   select the_address
   from some_table
   where identifier = address_id

然后要更改地址，我会调用另一个负责更改的 TAPI：

   ...
   change_address(address_id, new_address);
   ...

事务 API (XAPI) 又是无法直接访问以修改地址中的信息的地方。表，但我可以从中选择？ （这是我的理解有点模糊的地方）

要选择一个地址，我会：

   select the_address
   from some_table
   where identifier = address_id

然后要更改它，我会调用

   ...
   change_address(address_id, new_address);
   ...

所以我在 TAPI 和 XAPI 之间看到的唯一区别是方法从数据库中检索哪一条记录，即 Select 与 PL/SQL 调用？

是这样吗？或者我完全错过了重点？

Answer 1

表 API (TAPI) 是一个简单的 API，为表提供基本的 CRUD 操作。例如，如果我们有一个 tableR MYTABLE (id INTEGER PRIMARY KEY, text VACHAR2(30))，那么 TAPI 将类似于：

package mytable_tapi is
    procedure create_rec (p_id integer, p_text varchar2);
    procedure update_rec (p_id integer, p_text varchar2);
    procedure delete_rec (p_id integer);
    function get_rec (p_id integer) returns mytable%rowtype;
end;

当您使用 TAPI 时，每个表都有一个 TAPI，并且每个表都有一个 TAPI。插入、更新和删除都通过 TAPI 进行。

事务 API (XAPI) 是一种在事务级别而不是在单个 CRUD 级别工作的 API（尽管在某些情况下这将是同一件事）。例如，处理银行交易的 XAPI 可能如下所示：

package banking_xapi is
    procedure make_transfer (p_from_account integer, p_to_account integer,
                             p_amount number);
    ... -- other XAPI procs
end;

make_transfer 过程可能不执行单个插入、更新或删除。它可能会做这样的事情：

procedure make_transfer (p_from_account integer, p_to_account integer,
                         p_amount number)
is
begin
    insert into transfer_details (from_account, to_account, amount)
       values (p_from_account, p_to_account, p_amount);

    update accounts set balance = balance-p_amount
    where account_no = p_from_account;

    update accounts set balance = balance+p_amount
    where account_no = p_to_account;
end;

即它执行整个事务，该事务可能由1个或多个DML语句组成。

TAPI 支持者会说这是编码错误的，不应该包含 DML，而是调用 TAPI 代码，如下所示：

procedure make_transfer (p_from_account integer, p_to_account integer,
                         p_amount number)
is
begin
    transactions_tapi.insert_rec (p_from_account, p_to_account, p_amount);

    accounts_tapi.update_rec (p_from_account, -p_amount);

    accounts_tapi.update_rec (p_to_account, p_amount);
end;

其他人（例如 Tom Kyte 和我自己）会认为这是矫枉过正，没有增加任何实际价值。

因此，您可以单独使用 XAPI（Tom Kyte 的方式），也可以使用调用 TAPI 的 XAPI（Steve Feuerstein 的方式）。但有些系统只有 TAPI，这非常差 - 也就是说，它们将其留给用户界面的编写者来将必要的 TAPI 调用串在一起以构成事务。请参阅我的博客了解该方法的含义。

Answer 2

让我们从表 API 开始。这是通过 PL/SQL API 协调对表的访问的做法。因此，我们每个表都有一个包，它应该从数据字典生成。该包提供了一组用于针对表发出 DML 的标准过程以及一些用于检索数据的函数。

相比之下，事务 API 代表一个工作单元。它根本不公开有关底层数据库对象的任何信息。事务 API 提供更好的封装和更清晰的界面。

对比是这样的。创建新部门时请考虑以下业务规则：

1. 新部门必须有名称和地点
2. 新部门必须有一名经理，该经理必须是现有员工
3. 其他现有员工可能会调到新部门
4. 新员工可能会被分配到新部门新部门
5. 新部门必须至少分配两名员工（包括经理）

使用表 API，事务可能如下所示：

DECLARE
    dno pls_integer;
    emp_count pls_integer;
BEGIN
    dept_utils.insert_one_rec(:new_name, :new_loc, dno);
    emp_utils.update_one_rec(:new_mgr_no ,p_job=>'MGR’ ,p_deptno=>dno);
    emp_utils.update_multi_recs(:transfer_emp_array, p_deptno=>dno);
    FOR idx IN :new_hires_array.FIRST..:new_hires_array.LAST LOOP
        :new_hires_array(idx).deptno := dno;
    END LOOP;
    emp_utils.insert_multi_recs(:new_hires_array);
    emp_count := emp_utils.get_count(p_deptno=>dno); 
    IF emp_count < 2 THEN
        raise_application_error(-20000, ‘Not enough employees’);
    END IF;
END;
/

而使用事务 API 则要简单得多：

DECLARE
    dno subtype_pkg.deptno;
BEGIN
    dept_txns.create_new_dept(:new_name
                                , :new_loc
                                , :new_mgr_no
                                , :transfer_emps_array
                                , :new_hires_array
                                , dno);
END;
/

那么为什么检索数据方面存在差异呢？因为事务 API 方法不鼓励通用 get() 函数，以避免盲目使用低效的 SELECT 语句。

例如，如果您只想要某个 Employee 的工资和佣金，则查询此 ...

select sal, comm
into l_sal, l_comm
from emp
where empno = p_eno;

... 比执行此 ... ... 更好

l_emprec := emp_utils.get_whole_row(p_eno);

，尤其是当 Employee 记录具有 LOB 列时。

它也比：

l_sal := emp_utils.get_sal(p_eno);
l_comm := emp_utils.get_comm(p_eno);

...如果每个 getter 执行单独的 SELECT 语句更有效。这是众所周知的：这是一种糟糕的面向对象实践，会导致可怕的数据库性能。

Table API 的支持者之所以支持它们，是因为它们使开发人员无需考虑 SQL。出于同样的原因，反对它们的人不喜欢 Table API。即使是最好的 Table API 也倾向于鼓励 RBAR 处理。如果我们每次都编写自己的 SQL，我们更有可能选择基于集合的方法。

使用事务 API 并不一定排除使用 get_resultset() 函数。查询 API 仍然有很多价值。但它更有可能是由实现联接的视图和函数构建的，而不是单个表上的 SELECT。

顺便说一句，我认为在表 API 之上构建事务 API 并不是一个好主意：我们仍然有孤立的 SQL 语句，而不是精心编写的联接。

作为说明，以下是事务 API 的两种不同实现，用于更新某个区域中每个员工的工资（区域是组织的一个大型部分；部门分配给区域）。

第一个版本没有纯 SQL，只有 Table API 调用，我不认为这是一个稻草人：它使用了我在 Table API 包中看到的功能（尽管有些使用动态 SQL 而不是命名的 SET_XXX() 过程） 。

create or replace procedure adjust_sal_by_region
    (p_region in dept.region%type
           , p_sal_adjustment in number )
as
    emps_rc sys_refcursor;
    emp_rec emp%rowtype;
    depts_rc sys_refcursor;
    dept_rec dept%rowtype;
begin
    depts_rc := dept_utils.get_depts_by_region(p_region);

    << depts >>
    loop
        fetch depts_rc into dept_rec;
        exit when depts_rc%notfound;
        emps_rc := emp_utils.get_emps_by_dept(dept_rec.deptno);

        << emps >>
        loop
            fetch emps_rc into emp_rec;
            exit when emps_rc%notfound;
            emp_rec.sal := emp_rec.sal * p_sal_adjustment;
            emp_utils.set_sal(emp_rec.empno, emp_rec.sal);
        end loop emps;

    end loop depts;

end adjust_sal_by_region;
/

SQL 中的等效实现：

create or replace procedure adjust_sal_by_region
    (p_region in dept.region%type
           , p_sal_adjustment in number )
as
begin
    update emp e
    set e.sal = e.sal * p_sal_adjustment
    where e.deptno in ( select d.deptno 
                        from dept d
                        where d.region = p_region );
end adjust_sal_by_region;
/

这比以前版本的嵌套游标循环和单行更新要好得多。这是因为在 SQL 中，编写我们需要按地区选择员工的联接很容易。使用Table API要困难得多，因为Region不是Employees的键。

公平地说，如果我们有一个支持动态 SQL 的 Table API，情况会好一些，但仍然不理想：

create or replace procedure adjust_sal_by_region
    (p_region in dept.region%type
           , p_sal_adjustment in number )
as
    emps_rc sys_refcursor;
    emp_rec emp%rowtype;
begin
    emps_rc := emp_utils.get_all_emps(
                    p_where_clause=>'deptno in ( select d.deptno 
                        from dept d where d.region = '||p_region||' )' );

    << emps >>
    loop
        fetch emps_rc into emp_rec;
        exit when emps_rc%notfound;
        emp_rec.sal := emp_rec.sal * p_sal_adjustment;
        emp_utils.set_sal(emp_rec.empno, emp_rec.sal);
    end loop emps;

end adjust_sal_by_region;
/

---

最后一句话 话

虽如此，在某些情况下 Table API 会很有用，即当我们只想以相当标准的方式与单个表交互。一个明显的例子可能是生成或使用来自其他系统（例如 ETL）的数据源。

如果您想研究 Table API 的使用，最好的起点是 Steven Feuerstein 的 Quest CodeGen Utility （以前称为 QNXO）。这与 TAPI 生成器所能得到的一样好，而且是免费的。