在 Actionscript 3 (Flex) 中扩展数组

Question

我正在尝试对 Array 进行变体以达到非常特定的目的。当我有以下问题时：

public class TileArray extends Array {
   // Intentionally empty - I get the error regardless
}

为什么我不能这样做？

var tl:TileArray = [1,2,3];

尽管我可以做到这一点，但

var ar:Array = [1,2,3];

我收到的错误是这样的：

将静态类型数组的值隐式强制为可能不相关的类型

Answer 1

您可以编写自己的类来公开 Array 的所有方法，而不是扩展 Array。通过使用 Proxy 类，您可以将所有默认数组方法重定向到内部数组，但仍然可以灵活地添加您自己的方法：

package
{
    import flash.utils.flash_proxy;
    import flash.utils.Proxy;

    use namespace flash_proxy;

    dynamic public class ExampleArray extends Proxy
    {
        private var _array:Array;

        public function ExampleArray(...parameters)
        {
            _array = parameters;
        }

        override flash_proxy function callProperty( name:*, ...rest):* 
        {
            return _array[name].apply(_array, rest);

        }

        override flash_proxy function getProperty(name:*):* 
        {
            return _array[name];
        }

        override flash_proxy function setProperty(name:*, value:*):void 
        {
            _array[name] = value;
        }

        public function getSmallestElement():*
        {
            var helper:Array = _array.concat().sort();
            return helper[0];
        }

    }
}

例如：

var test:ExampleArray = new ExampleArray(8,7,6,5,4,3,2,1);
trace( test.getSmallestElement()); // 1
test.sort();
trace(test); // 1,2,3,4,5,6,7,8 

Answer 2

[] 只创建一个数组。它不能用于创建 Array 的子类。

使用新功能“扩展”数组的好方法是编写操作常规数组的独立实用程序函数。最重要的是，这将允许您对任何数组执行任何操作，而不仅限于使用您的子类创建的数组。

下面是一个包含数组实用函数的类的简单示例：

package com.example.utils
{
    public class ArrayUtil
    {
        public static function traceArray( array:Array ):void
        {
            trace( array.length, "[" + array + "]" );
        }
    }
}

用法：

ArrayUtil.traceArray( [1, 2, 3] ); //output: 3 [1,2,3]

Answer 3

[1,2,3] 是 new Array(1,2,3) 的简写（或语法糖）。考虑到这一点，代码失败的原因似乎就更明显了。

每个 TileArray 都是一个 Array，因为 TileArray 扩展了 Array，但反之则不然：不是每个 >Array 是一个TileArray。因此，您不能在需要 TileArray 的地方传递 Array。这就是您收到编译器错误的原因。

转换只会将错误从编译时推迟到运行时，因为对象的实际类型是 Array，这确实与 TileArray 无关。

如果您想扩展 Array 功能（并且还能够添加一些语法糖），您可能需要考虑扩展 Proxy，正如已经建议的那样。请记住，它的性能较差，因此如果您打算大量使用此类，这可能不是最好的主意。