perl多任务问题

Question

我已经完成了我之前使用 Perl 线程的多线程程序，它可以在我的系统上运行。问题是，在它需要运行的某些系统上，线程支持未编译到 perl 中，并且我无法安装其他软件包。因此，我需要使用线程以外的其他东西，并且我正在将代码移至使用 fork()。这适用于我的 Windows 系统启动子任务。

几个问题：

1. 如何判断子进程何时退出？当线程计数低于某个值时，我创建了新线程，我需要跟踪正在运行的线程数量。对于进程，我如何知道一个进程何时退出，以便跟踪当时有多少个进程存在，当创建一个进程时递增计数器，当一个退出时递减计数器？

2. 当父进程打开时，使用通过 OPEN 获得的句柄进行文件 I/O 在子进程中是否安全？我需要为每个子进程附加一个文件，这在 UNIX 上也安全吗？

3. 除了 fork 和 thread 之外还有其他选择吗？我尝试使用 Parallel::ForkManager，但它没有安装在我的系统上（使用 Parallel::ForkManager；给出了错误），并且我绝对要求我的 perl 脚本在所有 unix/windows 系统上工作，而无需安装任何其他模块。< /p>

Answer 1

典型用法：

use POSIX ':sys_wait_h';    # for &WNOHANG

# how to create a new background process
$pid = fork();
if (!defined $pid) { die "fork() failed!" }
if ($pid == 0) { # child
    # ... do stuff in background ...
    exit 0;      # don't forget to exit or die from the child process
} 
# else this is the parent, $pid contains process id of child process
# ... do stuff in foreground ...

# how to tell if a process is finished
# also see  perldoc perlipc
$pid = waitpid -1, 0;           # blocking wait for any process
$pid = wait;                    # blocking wait for any process
$pid = waitpid $mypid, 0;       # blocking wait for process $mypid
# after blocking wait/waitpid
if ($pid == -1) {
    print "All child processes are finished.\n";
} else {
    print "Process $pid is finished.\n";
    print "The exit status of process $pid was $?\n";
}

$pid = waitpid -1, &WNOHANG;    # non-blocking wait for any process
$pid = waitpid $mypid, 0;       # blocking wait for process $mypid
if ($pid == -1) {
    print "No child processes have finished since last wait/waitpid call.\n";
} else {
    print "Process $pid is finished.\n";
    print "The exit status of process $pid was $?\n";
}

# terminating a process - see  perldoc -f kill  or  perldoc perlipc
# this can be flaky on Windows
kill 'INT', $pid;               # send SIGINT to process $pid

perldoc -f fork 中的详细信息， waitpid，等待，kill 和 perlipc。 perlipc 中有关为 SIGCHLD 事件设置处理程序的内容应该特别有用，尽管 Windows 不支持这一点。

在 Unix 和 Windows 上，跨分叉进程的 I/O 通常是安全的。文件描述符是共享的，因此对于类似的事情，

open X, ">", $file;
if (fork() == 0) {  # in child
    print X "Child\n"; 
    close X;
    exit 0;
}
# in parent
sleep 1;
print X "Parent\n";
close X;

子进程和父进程都将成功写入同一个文件（但请注意输出缓冲）。

Answer 2

看一下 waitpid。下面是一些需要完成九个任务（1 到 9）的代码。它将启动最多三名工作人员来完成这些任务。

#!/usr/bin/perl

use strict;
use warnings;
use POSIX ":sys_wait_h";

my $max_children = 3;
my %work = map { $_ => 1 } 1 .. 9;
my @work = keys %work;

my %pids;
while (%work) {
    #while there are still empty slots
    while (@work and keys %pids < $max_children) {
        #get some work for the child to do
        my $work = shift @work;

        die "could not fork" unless defined(my $pid = fork);

        #parent
        if ($pid) {
            $pids{$pid} = 1;
            next;
        }

        #child
        print "$ doing work $work\n";
        sleep 1;
        print "$ done doing work $work";
        exit $work;
    }

    my $pid = waitpid -1, WNOHANG;

    if ($pid > 0) {
        delete $pids{$pid};
        my $rc = $? >> 8; #get the exit status
        print "saw $pid was done with $rc\n";
        delete $work{$rc};
        print "work left: ", join(", ", sort keys %work), "\n";
    }

    select undef, undef, undef, .25;
}