如何获取winexec或shellexecute中执行的Handle？

Question

我用来创建一个自定义函数，如 winexec(...):Hwnd ，它将重新调整执行的应用程序的句柄。

我确实使用了 findwindow() 但如果它更改窗口标题就会出现问题。

Answer 1

没有一种通用方法可以获取应用程序的“该”窗口句柄，因为不能保证任何程序都有一个窗口句柄。一个程序可能有许多顶级句柄（即，Microsoft Word，每个文档一个），或者它可能根本没有窗口。您可能会问您真正需要窗口句柄的目的是什么？可能有更好的方法来做你想做的事情，不需要任何特定的窗口句柄。

WinExec（它已被弃用近 15 年了，因此您应该认真考虑不再使用它）和 ShellExecute 绝对不返回有关它们启动的程序的信息，如果它们确实如此启动任何程序。 （ShellExecute 可能使用 DDE 将命令发送到已运行的应用程序实例。）如果他们启动应用程序，它可能会在您的程序继续运行之前完成运行。

您可以使用 CreateProcess 或 ShellExecuteEx 代替。如果他们启动一个程序，他们会给您一个代表他们启动的程序的进程句柄。您可以使用它来帮助您获取有关该程序的其他信息，例如其窗口列表。不用费心FindWindow；标题和窗口类不保证是唯一的；一个程序可能对许多不同的窗口使用相同的类名，并且程序的多个实例将使用相同的类名，而没有太多方法来选择您真正想要的类名。

EnumWindows 是一个可用于获取候选窗口句柄列表的函数。您给它一个函数指针，它将为桌面上的每个顶级窗口调用该函数一次。您需要一种方法来告诉它您对哪个进程感兴趣，以及一种让它返回结果列表的方法。该函数只接受一个参数，因此该参数必须是一个指向包含更多信息的结构的指针：

type
  PWindowSearch = ^TWindowSearch;
  TWindowSearch = record
    TargetProcessID: DWord;
    ResultList: TWndList;
  end;

TWndList 是我创建的一种类型，用于保存 HWnd 列表> 价值观。如果您有 Delphi 2009 或更高版本，则可以使用 TList；对于早期版本，您可以使用 TList 后代或您选择的任何其他内容。

CreateProcess 将告诉您它填充的 TProcessInformation 记录的 dwProcessID 成员中的新进程 ID； ShellExecuteEx 仅返回进程句柄，因此请使用 GetProcessID 就可以了。窗口枚举函数需要一个与此签名匹配的回调函数：

function SelectWindowByProcessID(Wnd: HWnd; Param: LParam): Bool; stdcall;

您可以使用 EnumWindows 来获取如下句柄列表：

function GetWindowListByProcessID(pid: DWord): TWndList;
var
  SearchRec: TWindowSearch;
begin
  Result := TWndList.Create;
  try
    SearchRec.TargetProcessID := pid;
    SearchRec.ResultList := Result;
    Win32Check(EnumWindows(SelectWindowByProcessID, LParam(@SearchRec)));
  except
    Result.Free;
    raise;
  end;
end;

您将像这样实现回调函数：

function SelectWindowByProcessID(Wnd: HWnd; Param: LParam): Bool; stdcall;
var
  SearchRec: PWindowSearch;
  WindowPid: DWord;
begin
  SearchRec := PWindowSearch(Param);
  Assert(Assigned(SearchRec));
  GetWindowThreadProcessID(Wnd, WindowPid);
  if WindowPid = SearchRec.TargetProcessID then
    SearchRec.ResultList.Add(Wnd);
  Result := True;
end;

一旦获得列表，您就可以检查窗口的其他属性以确定哪些属性确实是您想要的。您可以通过窗口标题或类名，或者通过属于该窗口的其他控件来确定它。

使用完进程句柄后，请确保对其调用 CloseHandle ，以便操作系统可以清理进程的簿记信息。

Answer 2

有一个名为 EnumWindows 的函数。
我认为这对你有用。

检查以下链接以获取更多信息

http://delphi.about.com/od /windowsshellapi/l/aa080304a.htm

http://www. swissdelphicenter.ch/terry/showcode.php?id=327

Answer 3

尝试此页面 (http://delphidabbler.com/tips/134) 中的示例 6，然后对其进行修改一点点。我就是这么做的。

如果你想分开你检查的地方和你审查结果的地方，你可以做类似的事情，

var
  //...
  runNext : Boolean;
  //...

begin
{ startup code from other sample here }

// but instead of if
runNext := ShellExecuteEx(@SEInfo);

{ some more code here }

    // need delay before running next process
    // run loop until window with Handle is closed
if runNext then
    with SEInfo do
     repeat
      GetExitCodeProcess(SEInfo.hProcess, ExitCode);
      Sleep(20);
      Application.ProcessMessages;
      CheckSynchronize();
    until (ExitCode <> STILL_ACTIVE) or Application.Terminated;

{ next process code here }
end;

我意识到你们中的一些人会因为扔进 Sleep() 而在这上面投下仇恨邮件，但我不想锁定窗口，直到执行完毕当我正在处理一大堆东西并等待时就完成了。