XSLT 字符串替换

Question

我不太了解 XSL，但我需要修复此代码，我已减少它以使其更简单。
我收到这个错误

无效的 XSLT/XPath 函数

此行上的

<xsl:variable name="text" select="replace($text,'a','b')"/>

这是 XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

谁能告诉我它有什么问题吗？

Answer 1

replace 不适用于 XSLT 1.0。

Codesling 有一个 string-replace 模板 您可以用作函数的替代：

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

调用为：

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

另一方面，如果您实际上只需要用另一个字符替换一个字符，则可以调用 translate 具有类似的签名。像这样的东西应该可以正常工作：

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

另外，请注意，在本示例中，我将变量名称更改为“newtext”，在 XSLT 中变量是不可变的，因此您不能执行与 $foo = $foo 等效的操作code> 就像您在原始代码中一样。

Answer 2

下面是 XSLT 函数，其工作方式与 C# 的 String.Replace() 函数类似。

该模板有 3 个参数如下

text :- 您的主字符串

replace :- 您想要替换的字符串

by :- 字符串它将通过新字符串回复

下面是模板

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

下面的示例展示了如何调用它

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

您还可以参考 以下 URL 了解详细信息。

Answer 3

我一直点击这个答案。但它们都没有列出 xsltproc（可能还有大多数 XSLT 1.0 处理器）的最简单解决方案：

1. 将 exslt 字符串名称添加到样式表中，即：

<xsl:stylesheet
  version="1.0"
  xmlns:str="http://exslt.org/strings"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

2. 然后像这样使用它：

<xsl:value-of select="str:replace(., ' ', '')"/>

Answer 4

注意：如果您希望在需要替换源字符串中大量实例（例如长文本中的新行）的情况下使用已经提到的算法，则有 high< /em> 由于递归调用，您最终可能会遇到 StackOverflowException 。

感谢 Xalan 的内置 Java 类型嵌入（没有了解如何在 Saxon 中做到这一点），我解决了这个问题：

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

Answer 5

当您的处理器在 .NET Framework（不支持 .NET Core 或 .NET 5）上运行或使用 MSXML（与基于 Java 的处理器或其他本机处理器相对）时，您可以使用以下代码。它使用 msxsl:script。

确保将命名空间 xmlns:msxsl="urn:schemas-microsoft-com:xslt" 添加到根 xsl:stylesheet 或 xsl:transform 元素。

此外，将 outlet 绑定到您喜欢的任何命名空间，例如 xmlns:outlet = "http://my.functions"。

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

Answer 6

添加 case:

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

该例程非常好，但是它导致我的应用程序挂起，因此我需要在函数被递归调用之前

。我从这里得到了答案：
当测试挂在无限循环中

谢谢！