执行方法失败的消息原因

Question

我使用 DAO 方法 Execute 删除一些记录。如果失败，可以通过检查 RecordsAffected 来清除（将为 0）。但是是否有可能获取错误消息（例如，记录或显示给用户）？我尝试在表网格中手动删除记录，但收到一条清晰的对话框消息，例如“无法删除或更改记录，因为表 x 包含相关记录”。

Answer 1

在 Execute 方法中包含 dbFailOnError 选项以捕获 DELETE 错误。如果没有 dbFailOnError，您的 DELETE 可能会默默失败。

依靠 RecordsAffected 来指示 DELETE 失败可能会产生误导。例如，如果您的 DELETE 包括“WHERE Sample=5”，并且不存在 Sample 值为 5 的行，则 RecordsAffected 将为 0。这对数据库引擎来说不是错误。

在以下示例中，DELETE 失败，因为 tblParent 和 tblChild 之间存在关系（强制执行引用完整性）。因此，消息框显示“无法删除或更改记录，因为表‘tblChild’包含相关记录”。

Public Sub DeleteFailure()
    Dim strSql As String
    Dim strMsg As String
    Dim db As DAO.Database

On Error GoTo ErrorHandler

    strSql = "DELETE FROM tblParent WHERE id = 1;"
    Set db = CurrentDb
    db.Execute strSql, dbFailOnError

ExitHere:
    On Error GoTo 0
    Debug.Print "RecordsAffected: " & db.RecordsAffected
    Set db = Nothing
    Exit Sub

ErrorHandler:
    strMsg = "Error " & Err.Number & " (" & Err.Description _
        & ") in procedure DeleteFailure"
    MsgBox strMsg
    GoTo ExitHere
End Sub

更新：这是一个修改后的ErrorHandler，以适应DAO操作触发的多个错误。

ErrorHandler:
    Dim errLoop As Error
    Debug.Print "Errors.Count: " & Errors.Count
    For Each errLoop In Errors
        With errLoop
            strMsg = "Error " & Err.Number & " (" & _
                Err.Description & _
                ") in procedure DeleteFailure"
        End With
        MsgBox strMsg
    Next
    Set errLoop = Nothing
    GoTo ExitHere

Answer 2

应该可以使用 DBEngine 错误： http:// msdn.microsoft.com/en-us/library/bb177491(office.12).aspx