使用 Prolog 解决逻辑难题

Question

犯罪者属于 A、B、C、D 之一。

A 说：“这不是我”
B 说：“是 D”
C 说：“是 B”
D 说：“这不是我”

我们知道他们中只有一个人说的是实话。

到底是谁呢？我想用Prolog来解决这个问题。

这是一道面试题。

Answer 1

免责声明：这是Xonix的解决方案。如果您喜欢，请投票他。但由于我花了一些心思才弄清楚发生了什么，我想我不妨提出我的评论，以便其他人受益。

首先，这是他作为适当子句的解决方案：

criminal(K):-
    member(K,[a,b,c,d]),
    (K\=a -> A=1;A=0),
    (K=d  -> B=1;B=0),
    (K=b  -> C=1;C=0),
    (K\=d -> D=1;D=0),
    A+B+C+D=:=1.

它是这样的：

首先，他遍历个体列表（必须是小写，因此它们不是变量）。 K 依次实例化到它们中的每一个。

对于 K 的每个可能值，他都会遍历该子句的其余部分。 K 可以解释为假设罪犯是谁。接下来的 4 行是为每个变量 A、B、C 和 D 提供绑定。您可以这样阅读它们： 假设 a 不是罪犯，则 a 是真实的，否则不是。假设d是罪犯，b是真实的，否则不是。阿斯夫。也就是说，变量 A、B……捕捉了给定特定罪犯的相应个体的真实性。

由于已知约束条件是只有其中一个是真实的，因此它们的真值之和必须为 1。回溯时，Prolog 为 K 进行下一个绑定，并再次运行它。事实证明，只有当 a 是罪犯时（并且 d 说的是实话，如果我没记错的话），这个约束才被满足。可爱的。

Answer 2

这是另一个解决方案，我发现它比 Xonix 的解决方案要简单一些。
在 SWI-Prolog 中测试。

% To find a criminal and the truthteller
% 1. Pick a possible criminal
% 2. Pick a possible truthteller and the remaining liars
% 3. Assert that the truthteller's statement is the truth
% 4. Assert that every liar's statement is not the truth
% If both the assertions succeed
% then we have found a criminal and the truthteller.
criminal_and_truthteller(Criminal, Truthteller) :-
    Group = [a, b, c, d],
    member(Criminal, Group),
    select(Truthteller, Group, Liars),
    statement(Truthteller, Criminal, Truth),
    Truth,
    forall(
        member(Liar, Liars),
        (statement(Liar, Criminal, Lie), \+ Lie)
    ).

% Statements
% Arg 1: Who says
% Arg 2: About whom
% Arg 3: Which statement
% e.g. "a claims that a is not a criminal"
statement(a, C, a \= C).
statement(b, C, d  = C).
statement(c, C, b  = C).
statement(d, C, d \= C).

使用示例：

?- criminal_and_truthteller(Criminal, Truthteller).
Criminal = a,
Truthteller = d ;
false.

Answer 3

我遇到了这个问题并想尝试一下：

a(K) :- K \== a.
b(d).
c(b).
d(K) :- K \== d.

solve(TruthTeller) :-
    member(K, [a, b, c, d]),
    xor([a(K), b(K), c(K), d(K)], Truth),
    Truth =.. [TruthTeller|_].

xor([Head|Tail], Result) :-
    (   call(Head)
     -> forall(member(X, Tail), \+ call(X)), Result = Head
     ;  xor(Tail, Result)).

Answer 4

类似的问题和相应的解决方案也可以在这里找到：

https： //github.com/LogtalkDotOrg/logtalk3/blob/master/examples/puzzles/jam_thief.lgt

与 Kaarel 发布的解决方案一样，可以请求对找到的解决方案进行论证/解释。

Answer 5

单线解决方案

?- member(K,[a,b,c,d]),(K\=a->A=1;A=0),(K=d->B=1;B=0),(K=b->C=1;C=0),(K\=d->D=1;D=0),A+B+C+D=:=1.
K = a,
A = 0,
B = 0,
C = 0,
D = 1 ;
false.