在 perl 中重定向输出时 fork exec Kill 出现问题

Question

我在 perl 中创建了一个脚本来运行带有超时的程序。如果正在执行的程序花费的时间比超时时间长，则脚本会终止该程序并返回消息“TIMEOUT”。

该脚本运行得很好，直到我决定重定向执行程序的输出。

当 stdout 和 stderr 被重定向时，脚本执行的程序不会被终止，因为它的 pid 与我从 fork 获得的 pid 不同。

看起来 perl 执行的 shell 在重定向的情况下执行我的程序。

我希望有输出重定向，但仍然能够在超时的情况下终止程序。

关于我如何做到这一点有什么想法吗？

我的脚本的简化代码是：

#!/usr/bin/perl

use strict;
use warnings;
use POSIX ":sys_wait_h";

my $timeout = 5;
my $cmd = "very_long_program 1>&2 > out.txt";

my $pid = fork();
if( $pid == 0 )
{
   exec($cmd) or print STDERR "Couldn't exec '$cmd': $!";
   exit(2);
}
my $time = 0;
my $kid = waitpid($pid, WNOHANG);
while ( $kid == 0 )
{
   sleep(1);
   $time ++;
   $kid = waitpid($pid, WNOHANG);
   print "Waited $time sec, result $kid\n";
   if ($timeout > 0 && $time > $timeout)
   {
      print "TIMEOUT!\n";
      #Kill process
      kill 9, $pid;
      exit(3);
   }
}

if ( $kid == -1)
{
   print "Process did not exist\n";
   exit(4);
}
print "Process exited with return code $?\n";
exit($?);

感谢您的帮助。

Answer 1

尝试将 $cmd 从 更改

my $cmd = "very_long_program 1>&2 > out.txt";

为

my $cmd = "exec very_long_program 1>&2 > out.txt";

exec 将告诉由 perl 生成的 shell 将其自身替换为very_long_program，而不是作为子进程运行very_long_program。

（在这种情况下，perl 生成 shell 的原因是因为 $cmd 包含重定向字符 - 而 perl 本身不知道如何处理它们。解决该问题的另一种方法是进行重定向在 Perl 本身中，在 fork() 之后但在调用 exec() 之前 - 但这有点棘手，所以首先尝试 exec 解决方法！）

Answer 2

另一种方法是在 fork 之后重定向 STDOUT 和 STDERR 并在不重定向的情况下运行命令：

open(STDOUT, ">", "out.txt") or die "Err: $!";
open(STDERR, ">&STDOUT");
exec("very_long_command");
die "Failed to exec very_long_command: $!";