HMAC SHA1 ColdFusion

Question

请帮忙！我一直在为这个拔头发。 :)

我有一个网站需要 HMAC SHA1 进行身份验证。它目前可以使用另一种语言，但现在我需要将其转移到 ColdFusion。对于我的一生，我无法让琴弦相匹配。任何帮助将不胜感激。

数据：https%3A%2F%2Fwww%2Etestwebsite%2Ecom%3Fid%3D5447
密钥：<代码>265D5C01D1B4C8FA28DC55C113B4D21005BB2B348859F674977B24E0F37C81B05FAE85FB75EA9CF53ABB9A174C59D98C7A61E2985026D2AA70AE4452A6E3F2 F9

正确答案：WJd%2BKxmFxGWdb​​w4xQJZXd3%2FHkFQ%3d
我的答案：knIVr6wIt6%2Fl7mBJPTTbwQoTIb8%3d

两者都是Base64编码，然后URL编码。

Answer 1

我自己做一个 HMAC-SHA1 的事情。我能说的最多的是我找到了这个旧功能。到目前为止，对我正在做的事情非常有效。忘了在哪里找到它，所以我不能相信作者。

对于您的 Base 64 内容...在加密上运行此函数，然后只需对返回的内容执行 cfset newString = toBase64(oldString) 即可。

<cffunction name="hmacEncrypt" returntype="binary" access="public" output="false">
   <cfargument name="signKey" type="string" required="true" />
   <cfargument name="signMessage" type="string" required="true" />
   <cfargument name="algorithm" type="string" default="HmacSHA1" />
   <cfargument name="charset" type="string" default="UTF-8" />

   <cfset var msgBytes = charsetDecode(arguments.signMessage, arguments.charset) />
   <cfset var keyBytes = charsetDecode(arguments.signKey, arguments.charset) />
   <cfset var keySpec = createObject("java","javax.crypto.spec.SecretKeySpec")  />
   <cfset var mac = createObject("java","javax.crypto.Mac") />

   <cfset key = keySpec.init(keyBytes, arguments.algorithm) />
   <cfset mac = mac.getInstance(arguments.algorithm) />
   <cfset mac.init(key) />
   <cfset mac.update(msgBytes) />

   <cfreturn mac.doFinal() />
</cffunction>

Answer 2

更短的加密方法（基于 Barney's方法）输出字符串：

<cffunction name="CFHMAC" output="false" returntype="string">
   <cfargument name="signMsg" type="string" required="true" />
   <cfargument name="signKey" type="string" required="true" />
   <cfargument name="encoding" type="string" default="utf-8" />
   <cfset var key = createObject("java", "javax.crypto.spec.SecretKeySpec").init(signKey.getBytes(arguments.encoding), "HmacSHA1") />
   <cfset var mac = createObject("java", "javax.crypto.Mac").getInstance("HmacSHA1") />
   <cfset mac.init(key) />
   <cfreturn toBase64(mac.doFinal(signMsg.getBytes(arguments.encoding))) />
</cffunction>

此外，

1. ColdFusion 10 本身支持 HMAC-SHA1 进行加密和散列。
2. 有一个名为 CF_HMAC 由 Adob​​e 分发的库
3. 有几个库在为 Amazon 签名文件时处理相关的 HMAC。其中包括 cf-amazon-s3、Barney 的 S3 URL 生成器 和 RIAForge S3

Answer 3

史蒂夫 - 感谢您的回复。我实际上已经在使用 hmacEncrypt 函数了。不过我确实弄清楚了我的问题。我传递的是十六进制键而不是字符串。它接受了密钥，因为从技术上讲它是一个字符串。为了将其恢复为字符串，除了上面的函数之外，我还使用了另一个函数。下面的代码将十六进制更改为字符串。我没有编写下面的函数，也不记得它从哪里获得作者的认可，但它效果很好。

<cffunction name="Hex2Bin" returntype="any" hint="Converts a Hex string to binary">
    <cfargument name="inputString" type="string" required="true" hint="The hexadecimal string to be written.">
    <cfset var outStream = CreateObject("java", "java.io.ByteArrayOutputStream").init()>
    <cfset var inputLength = Len(arguments.inputString)>
    <cfset var outputString = "">
    <cfset var i = 0>
    <cfset var ch = "">
    <cfif inputLength mod 2 neq 0>
    <cfset arguments.inputString = "0" & inputString>
    </cfif>
    <cfloop from="1" to="#inputLength#" index="i" step="2">
        <cfset ch = Mid(inputString, i, 2)>
        <cfset outStream.write(javacast("int", InputBaseN(ch, 16)))>
    </cfloop>
    <cfset outStream.flush()>
    <cfset outStream.close()> 
    <cfreturn outStream.toByteArray()>
</cffunction>