groovy 中的 splat 运算符？

Question

def foo(map, name) {
  println(map)
}

foo("bar", hi: "bye")

。

[hi:bye]

现在我有一张以前的地图，我希望将其传递给 foo 在伪代码中，类似：

def otherMap = [hi: "world"]
foo("bar", hi: "bye", otherMap*)

这样它就打印出来

[hi:world]

这当然是行不通的。

另外，尝试仅传递地图会混合参数的顺序：

def otherMap = [hi: "world"]
foo("bar", otherMap)

将打印

bar

如何解决此问题？

Answer 1

您正在寻找展开地图运算符。

def foo(map, name) {
  println(map)
}

foo("bar", hi: "bye")

def otherMap = [hi: "world"]
foo("bar", hi: "bye", *:otherMap)
foo("bar", *:otherMap, hi: "bye")

印刷：

["hi":"bye"]
["hi":"world"]
["hi":"bye"]

Answer 2

我不确定您到底想要实现什么，所以这里有几种可能性：

如果您想将第二个地图中的内容添加到第一个地图中，则 leftShift 运算符是正确的方法：

def foo(name, map) {
  println(map)
}

def otherMap = [hi: "world"]
foo("bar", [hi: "bye"] << otherMap)

如果您想通过参数访问参数name 使用 Map：

def foo(Map args) {
  println args.map
}

def otherMap = [hi: "world"]
foo(name:"bar", first:[hi: "bye"], map:otherMap)

如果要打印所有参数或仅打印最后一个参数，请使用 varargs：

def printLast(Object[] args) {
  println args[-1]
}

def printAll(Object[] args) {
  args.each { println it }
}

def printAllButName(name, Map[] maps) {
  maps.each { println it }
}

def otherMap = [hi: "world"]
printLast("bar", [hi: "bye"], otherMap)
printAll("bar", [hi: "bye"], otherMap)
printAllButName("bar", [hi: "bye"], otherMap)