CMake add_custom_command 未运行

Question

我正在尝试使用 add_custom_command 生成文件在构建期间。该命令似乎从未运行过，所以我制作了这个测试文件。

cmake_minimum_required( VERSION 2.6 )

add_custom_command(
  OUTPUT hello.txt
  COMMAND touch hello.txt
  DEPENDS hello.txt
)

我尝试运行：

cmake .  
make

并且未生成 hello.txt。我做错了什么？

Answer 1

当您只有一个正在构建的目标时，add_custom_target(run ALL ...) 解决方案适用于简单的情况，但当您有多个顶级目标（例如应用程序和测试）时，该解决方案就会崩溃。

我跑了当我尝试将一些测试数据文件打包到目标文件中时，我遇到了同样的问题，这样我的单元测试就不会依赖于任何外部内容，我使用 add_custom_command 和一些额外的依赖魔术来解决它。 code>set_property。

add_custom_command(
  OUTPUT testData.cpp
  COMMAND reswrap 
  ARGS    testData.src > testData.cpp
  DEPENDS testData.src 
)
set_property(SOURCE unit-tests.cpp APPEND PROPERTY OBJECT_DEPENDS testData.cpp)

add_executable(app main.cpp)
add_executable(tests unit-tests.cpp)

因此，现在 testData.cpp 将在编译 unit-tests.cpp 之前生成，并且只要 testData.src 发生变化，如果您调用的命令非常慢，您就会得到额外的好处。只构建应用程序目标，您不必等待该命令（只有测试可执行文件需要）完成，

上面没有显示，但要小心应用 ${PROJECT_BINARY_DIR}、${PROJECT_SOURCE_DIR} 和 include_directories。 () 将使您的源代码树中没有生成的文件。

Answer 2

两个现有答案的问题在于，它们要么使依赖项全局化（add_custom_target(name ALL ...)），要么将其分配给特定的单个文件（set_property(.. .)) 如果您有许多文件需要它作为依赖项，这会变得令人讨厌。相反，我们想要的是一个可以依赖另一个目标的目标。

执行此操作的方法是使用 add_custom_command 定义规则，然后使用 add_custom_target 基于该规则定义新目标。然后，您可以通过 add_dependency 将该目标添加为另一个目标的依赖项。

# this defines the build rule for some_file
add_custom_command(
  OUTPUT some_file
  COMMAND ...
)
# create a target that includes some_file, this gives us a name that we can use later
add_custom_target(
  some_target
  DEPENDS some_file
)
# then let's suppose we're creating a library
add_library(some_library some_other_file.c)
# we can add the target as a dependency, and it will affect only this library
add_dependencies(some_library some_target)

这种方法的优点：

• some_target 不是 ALL 的依赖项，这意味着您仅在特定目标需要时才构建它。 （而 add_custom_target(name ALL ...) 将为所有目标无条件地构建它。）
• 因为 some_target 是整个库的依赖项，所以它将在之前构建该库中的所有文件。这意味着如果库中有很多文件，我们不必对每个文件都执行 set_property 操作。
• 如果我们将 DEPENDS 添加到 add_custom_command 中，那么只有当其输入发生变化时，它才会被重建。 （将此与使用 add_custom_target(name ALL ...) 的方法进行比较，其中命令在每个构建上运行，无论是否需要。）

有关为什么会这样工作的更多信息，请参阅此博客文章： https://samthursfield.wordpress.com/2015/11/21/cmake-dependency- Between-targets-and-files-and-custom-commands/

Answer 3

添加以下内容：

add_custom_target(run ALL
    DEPENDS hello.txt)

如果您熟悉 makefile，这意味着：

all: run
run: hello.txt