在 Apple 地址簿中查找丢失的生日

Question

我正在尝试清除 Mac 地址簿中的漏洞。作为第一步，我想问我所有的朋友生日，以便能够通过 俗气的 Hallmark 卡。

我的地址簿中需要一个“组”，用于邮件合并个性化消息。

这是我想出的Applescript：

tell application "Address Book"

make new group with properties {name:"No Birthday"}

set birthdayPeople to (get every person whose birth date is greater than date "Monday, January 1, 1900 12:00:00 AM")

repeat with i from 1 to number of items in people

    set thePerson to item i of people

    if not (birthdayPeople contains thePerson) then
        add thePerson to group "No Birthday"
    end if

end repeat
save 
end tell

它崩溃了，但从错误消息中我无法推断出问题所在：

结果：错误“无法创建 «class azf4» ID \“05F770BA-7492-436B-9B58-E24F494702F8：ABP人\” 应用程序“地址簿”到 输入向量。”来自 «class 的数字 -1700 azf4» id “05F770BA-7492-436B-9B58-E24F494702F8:ABPerson”到矢量

（顺便说一句：我有没有提到这是我的第一个 AppleScript 代码？所以，如果这段代码可以简化，或者变得更优雅，那也是受欢迎的。）

Answer 1

我们可以将其简化为五行：

tell application "Address Book"
    add (every person whose birth date is missing value) to ¬
        make new group with properties {name:"No Birthday"}
    save addressbook
end tell

事实证明 add 可以获取列表以及单个对象，因此我们可以跳过循环。 （请注意，如果您使用了循环，则可以使用 repeat with thePerson in people ... end Repeat 形式，因为这比您使用的形式更清晰。）接下来，地址簿似乎将缺失的生日存储为缺失值（实际上是null），因此我们应该检查这一点，而不是与较早的日期进行比较。因此，为了获取没有生日的人的列表，我们写了每个出生日期缺失值的人，这正是它所说的。 whose 子句过滤前面的列表，使其仅包含与给定谓词匹配的值。然后，我们将该列表添加到我们内联创建的新组中。最后，save addressbook 保存更改并使其可见。

但是，在这种情况下，您根本不需要 AppleScript。地址簿支持智能群组；要创建一个，请按住 Option 键并单击“新建组”按钮。选择“无生日”作为智能组的名称，并告诉它匹配“生日”（来自第一个下拉列表）“未设置”（来自第二个下拉列表）的卡片。这将为您提供一组动态更新的没有设定生日的人。

---

编辑： 看来，虽然 add 在 Leopard 上采用了列表，但在 Snow Leopard 上却没有，因此我们需要使用显式的 repeat 循环（也适用于 Leopard）：

tell application "Address Book"
    set noBirthdays to make new group with properties {name:"No Birthday"}

    repeat with p in (every person whose birth date is missing value)
        add p to noBirthdays
    end repeat

    save addressbook
end tell

这与上述解决方案的工作方式几乎相同，只是我们预先进行分组，然后单独添加每个项目。我们不是迭代索引，而是直接迭代元素，因为这就是我们在这里关心的全部。

---

编辑：对于其他属性，情况类似；事实上，使用智能组时，情况是相同的。从 AppleScript 方面来看，问题在于数据的格式。大多数插槽在未设置时都会出现缺失值，但电子邮件是一个例外。通过测试我们可以看到，它们存储在一个列表中，因此我们需要每个电子邮件地址为 {} 的人。但是，这对我不起作用 - 可能是因为 email 是一个列表，但我不确定 - 所以你会想要

    repeat with p in every person
        if email of p is {} then add p to noEmails
    end repeat

瞧，一切都应该有效。

加入和排除企业也很容易，但据我所知，地址簿没有提供为他们创建智能组的方法。但是，相关属性是 company，对于企业来说为 true，对于其他企业来说为 false。因此，要创建一个没有公司的列表，您需要执行以下操作：

    repeat with p in (every person whose company is false)
        add p to noCompanies
    end repeat

如果您想要一个包含所有这些条件的主列表，有两种方法。首先，从 AppleScript 中，您获取两个条件和 and 它们，然后添加条件以判断他们是否有电子邮件：

    repeat with p in (every person whose company is false and ¬
                                         birth date is missing value)
        if email of p is {} then add p to masterGroup
    end repeat

另一个选项是从地址簿中执行此操作。您首先需要以 AppleScript 方式创建一个No Companies 组。然后，您创建一个匹配所有三个条件的智能组（使用 + 按钮添加它们）：“电子邮件未设置”、“生日未设置”和“卡是 ' 的成员”没有公司”。这可能是最好的选择，尽管不幸的是您必须将 AppleScript 用于 No Companies 组（我觉得应该有一种方法，但我看不到它是什么）。