MS Access (Jet) 事务、工作区

Question

我在提交事务（使用 Access 2003 DAO）时遇到问题。就好像我从未调用过 BeginTrans —— 我在 CommitTrans 上收到错误 3034，“您试图在没有首先开始事务的情况下提交或回滚事务”；并且更改将写入数据库（大概是因为它们从未包含在事务中）。但是，如果您单步执行，BeginTrans 就会运行。

• 我使用 DBEngine(0) 工作区在 Access 环境中运行它。
• 我要添加记录的表都是通过 Jet 数据库连接（到同一数据库）并使用 DAO.Recordset.AddNew / Update 打开的。
• 连接在启动 BeforeTrans 之前打开。
• 我没有在事务中间做任何奇怪的事情，例如关闭/打开连接或多个工作区等。
• 有两个嵌套事务级别。基本上，它将多个插入包装在外部事务中，因此如果有任何失败，它们都会失败。内部事务运行没有错误，外部事务不起作用。

以下是我研究并排除的一些事情：

• 事务分布在多个方法中，BeginTrans 和 CommitTrans（以及 Rollback）都位于不同的位置。但是，当我尝试以这种方式运行事务的简单测试时，似乎这并不重要。

• 我认为数据库连接可能会在超出本地范围时关闭，即使我有另一个对它的“全局”引用（老实说，我不确定 DAO 对数据库连接做了什么）。但情况似乎并非如此——就在提交之前，连接及其记录集处于活动状态（我可以检查它们的属性，EOF = False 等）

• 我的 CommitTrans 和 Rollback 是在事件回调中完成的。 （非常基本上：解析器程序在解析结束时抛出“onLoad”事件，我通过提交或回滚处理过程中所做的插入来处理该事件，具体取决于是否发生任何错误。）但是，再次尝试一个简单的测试，这似乎并不重要。

有什么想法为什么这对我不起作用吗？

谢谢。

5 月 25 日编辑

这是（简化的）代码。与事务有关的关键点是：

• 工作区是 DBEngine(0)，在公共（全局）变量 APPSESSION 中引用。
• 数据库连接在下面的 LoadProcess.cache 中打开，请参阅 Set db = APPSESSION.connectionTo(dbname_) 行。
• BeginTrans在LoadProcess.cache中被调用。
• CommitTrans 在 process__onLoad 回调中被调用。
• 在process__onInvalid回调中调用了rollback。
• 记录集更新在 process__onLoadRow、logLoadInit 和 logLoad

Eric中完成

'------------------- 
'Application globals
'-------------------

Public APPSESSION As DAOSession

'------------------
' Class LoadProcess
'------------------

Private WithEvents process_ As EventedParser
Private errs_ As New Collection

Private dbname_ As String
Private rawtable_ As String
Private logtable_ As String
Private isInTrans_ As Integer

Private raw_ As DAO.Recordset
Private log_ As DAO.Recordset
Private logid_ As Variant

Public Sub run
    '--- pre-load
    cache
    resetOnRun    ' resets load state variables per run, omitted here
    logLoadInit
    Set process_ = New EventedParser

    '--- load
    process_.Load
End Sub

' raised once per load() if any row invalid
Public Sub process__onInvalid(filename As String)
    If isInTrans_ Then APPSESSION.Workspace.Rollback
End Sub

' raised once per load() if all rows valid, after load
Public Sub process__onLoad(filename As String)
    If errs_.Count > 0 Then
        logLoadFail filename, errs_
    Else
        logLoadOK filename
    End If

    If isInTrans_ Then APPSESSION.Workspace.CommitTrans
End Sub

' raised once per valid row
' append data to raw_ recordset
Public Sub process__onLoadRow(row As Dictionary)
On Error GoTo Err_

    If raw_ Is Nothing Then GoTo Exit_   
    DAOext.appendFromHash raw_, row, , APPSESSION.Workspace

Exit_:
    Exit Sub

Err_:
    ' runtime error handling done here, code omitted
    Resume Exit_

End Sub


Private Sub cache()
Dim db As DAO.Database

    ' TODO raise error
    If Len(dbname_) = 0 Then GoTo Exit_       
    Set db = APPSESSION.connectionTo(dbname_)
    ' TODO raise error
    If db Is Nothing Then GoTo Exit_ 

    Set raw_ = db.OpenRecordset(rawtable_), dbOpenDynaset)
    Set log_ = db.OpenRecordset(logtable_), dbOpenDynaset)    

    APPSESSION.Workspace.BeginTrans
    isInTrans_ = True

Exit_:
    Set db = Nothing

End Sub

' Append initial record to log table
Private Sub logLoadInit()
Dim info As New Dictionary
On Error GoTo Err_

    ' TODO raise error?
    If log_ Is Nothing Then GoTo Exit_   

    With info
        .add "loadTime", Now
        .add "loadBy", CurrentUser
    End With

    logid_ = DAOext.appendFromHash(log_, info, , APPSESSION.Workspace)

Exit_:
    Exit Sub

Err_:
    ' runtime error handling done here, code omitted
    Resume Exit_

End Sub

Private Sub logLoadOK(filename As String)
    logLoad logid_, True, filename, New Collection
End Sub

Private Sub logLoadFail(filename As String, _
                      errs As Collection)
    logLoad logid_, False, filename, errs
End Sub

' Update log table record added in logLoadInit
Private Sub logLoad(logID As Variant, _
                    isloaded As Boolean, _
                    filename As String, _
                    errs As Collection)

Dim info As New Dictionary
Dim er As Variant, strErrs As String
Dim ks As Variant, k As Variant
On Error GoTo Err_

    ' TODO raise error?
    If log_ Is Nothing Then GoTo Exit_   
    If IsNull(logID) Then GoTo Exit_

    For Each er In errs
        strErrs = strErrs & IIf(Len(strErrs) = 0, "", vbCrLf) & CStr(er)
    Next Er

    With info
        .add "loadTime", Now
        .add "loadBy", CurrentUser
        .add "loadRecs", nrecs
        .add "loadSuccess", isloaded
        .add "loadErrs", strErrs
        .add "origPath", filename
    End With

    log_.Requery
    log_.FindFirst "[logID]=" & Nz(logID)
    If log_.NoMatch Then
        'TODO raise error
    Else
        log_.Edit
        ks = info.Keys
        For Each k In ks
            log_.Fields(k).Value = info(k)
        Next k
        log_.Update
    End If

Exit_:
    Exit Sub

Err_:
    ' runtime error handling done here, code omitted
    Resume Exit_

End Sub


'-------------
' Class DAOExt
'-------------
' append to recordset from Dictionary, return autonumber id of new record
Public Function appendFromHash(rst As DAO.Recordset, _
                          rec As Dictionary, _
                          Optional map As Dictionary, _
                          Optional wrk As DAO.workspace) As Long
Dim flds() As Variant, vals() As Variant, ifld As Long, k As Variant
Dim f As DAO.Field, rst_id As DAO.Recordset
Dim isInTrans As Boolean, isPersistWrk As Boolean
On Error GoTo Err_

    ' set up map (code omitted here)

    For Each k In rec.Keys
        If Not map.Exists(CStr(k)) Then _
            Err.Raise 3265, "appendFromHash", "No field mapping found for [" & CStr(k) & "]"
        flds(ifld) = map(CStr(k))
        vals(ifld) = rec(CStr(k))
        ifld = ifld + 1
    Next k

    If wrk Is Nothing Then
        isPersistWrk = False
        Set wrk = DBEngine(0)
    End If

    wrk.BeginTrans
        isInTrans = True
        rst.AddNew
        With rst
            For ifld = 0 To UBound(flds)
                .Fields(flds(ifld)).Value = vals(ifld)
            Next ifld
        End With
        rst.Update

        Set rst_id = wrk(0).OpenRecordset("SELECT @@Identity", DAO.dbOpenForwardOnly, DAO.dbReadOnly)
        appendFromHash = rst_id.Fields(0).Value

    wrk.CommitTrans
    isInTrans = False

Exit_:
    On Error GoTo 0
    If isInTrans And Not wrk Is Nothing Then wrk.Rollback
    If Not isPersistWrk Then Set wrk = Nothing
    Exit Function

Err_:
    ' runtime error handling, code omitted here
    Resume Exit_

End Function


'-----------------
' Class DAOSession (the part that deals with the workspace and dbase connections)
'-----------------
Private wrk_ As DAO.workspace
Private connects_ As New Dictionary
Private dbs_ As New Dictionary

Public Property Get workspace() As DAO.workspace
    If wrk_ Is Nothing Then
        If DBEngine.Workspaces.Count > 0 Then
            Set wrk_ = DBEngine(0)
        End If
    End If
    Set workspace = wrk_
End Property

Public Property Get connectionTo(dbname As String) As DAO.database
    connectTo dbname
    Set connectionTo = connects_(dbname)
End Property

Public Sub connectTo(dbname As String)
Dim Cancel As Integer
Dim cnn As DAO.database
Dim opts As Dictionary
    Cancel = False

    ' if already connected, use cached reference
    If connects_.Exists(dbname) Then GoTo Exit_

    If wrk_ Is Nothing Then _
        Set wrk_ = DBEngine(0)

    ' note opts is a dictionary of connection options, code omitted here
    Set cnn = wrk_.OpenDatabase(dbs_(dbname), _
                                CInt(opts("DAO.OPTIONS")), _
                                CBool(opts("DAO.READONLY")), _
                                CStr(opts("DAO.CONNECT")))

    ' Cache reference to dbase connection
    connects_.Add dbname, cnn

Exit_:
    Set cnn = Nothing
    Exit Sub

End Sub

Answer 1

通过定义一个工作区（不必是新的工作区）来使用事务，然后在该工作区上开始事务，执行您需要对其执行的操作，然后在一切正常的情况下提交事务。骨架代码：

  On Error GoTo errHandler
    Dim wrk As DAO.Workspace

    Set wrk = DBEngine(0) ' use default workspace
    wrk.BeginTrans
    [do whatever]
    If [conditions are met] Then
       wrk.CommitTrans
    Else
       wrk.Rollback
    End If

  errHandler:
    Set wrk = Nothing

  exitRoutine:
    ' do whatever you're going to do with errors
    wrk.Rollback
    Resume errHandler

现在，在您[做任何事情]的块中，您可以将工作区、数据库和记录集传递给子例程，但顶级控制结构应保留在一处。

您的代码不会这样做——相反，您依赖于全局变量。全局变量是邪恶的。不要使用它们。相反，将私有变量作为参数传递给要对其进行操作的子例程。我还要说，永远不要传递工作区 - 只传递您使用工作区创建的对象。

一旦你吸收了这一点，也许它会帮助你解释你的代码应该完成什么（我通过阅读它并没有最模糊的想法），然后我们可以建议你做错了什么。

Answer 2

好吧，经过多次令人沮丧的调试后，我想我发现了 Jet 事务中的一个错误。毕竟，它与我的“极其复杂”的代码或“邪恶的全局变量”无关:)

看来，当以下内容为真时，您会收到错误#3034：

• 您打开快照类型记录集
• 记录集是在开始事务之前打开
• 记录集在您开始事务之后、提交或回滚之前关闭/取消引用。

我还没有检查这是否已经知道，尽管我无法想象它不是。

当然，反正按照这个顺序做事情有点奇怪，自找麻烦，我也不知道为什么要这么做。我将打开/关闭快照记录集移至事务内，一切正常。

以下代码显示错误：

Public Sub run()
Dim db As DAO.Database, qdf As DAO.QueryDef, rst As DAO.Recordset
Dim wrk As DAO.Workspace, isInTrans As Boolean
On Error GoTo Err_

    Set wrk = DBEngine(0)
    Set db = wrk(0)
    Set rst = db.OpenRecordset("Table2", DAO.dbOpenSnapshot)

    wrk.BeginTrans
    isInTrans = True

    Set qdf = db.CreateQueryDef("", "INSERT INTO [Table1] (Field1, Field2) VALUES (""Blow"", ""Laugh"");")
    qdf.Execute dbFailOnError

Exit_:
    Set rst = Nothing
    Set qdf = Nothing
    Set db = Nothing
    If isInTrans Then wrk.CommitTrans
    isInTrans = False
    Exit Sub

Err_:
    MsgBox Err.Description
    If isInTrans Then wrk.Rollback
    isInTrans = False
    Resume Exit_

End Sub

这修复了错误：

Public Sub run()
Dim db As DAO.Database, qdf As DAO.QueryDef, rst As DAO.Recordset
Dim wrk As DAO.Workspace, isInTrans As Boolean
On Error GoTo Err_

    Set wrk = DBEngine(0)
    Set db = wrk(0)

    wrk.BeginTrans
    isInTrans = True

    ' NOTE THIS LINE MOVED WITHIN THE TRANSACTION
    Set rst = db.OpenRecordset("Table2", DAO.dbOpenSnapshot)

    Set qdf = db.CreateQueryDef("", "INSERT INTO [Table1] (Field1, Field2) VALUES (""Blow"", ""Laugh"");")
    qdf.Execute dbFailOnError

Exit_:
    Set rst = Nothing
    Set qdf = Nothing
    Set db = Nothing
    If isInTrans Then wrk.CommitTrans
    isInTrans = False
    Exit Sub

Err_:
    MsgBox Err.Description
    If isInTrans Then wrk.Rollback
    isInTrans = False
    Resume Exit_

End Sub

Answer 3

就其价值而言，这似乎比 Access 交易更为普遍。我刚刚使用 Access 2007 & 遇到了类似的情况。 DAO 作为 MySQL 的前端。使用 MySQL Autocommit=0，SQL 事务仍然会在事务进行到一半时神秘地提交自己。

经过两周的绞尽脑汁之后，我看到了这篇文章，并再次查看了我的代码。果然，MySQL 插入是由从 VBA 类模块内调用的存储过程完成的。该类模块有一个在 module.initialize() 上打开并在 terminate() 上关闭的 dao.recordset。此外，该记录集用于收集存储过程的结果。所以我（用伪代码......）

module.initialize - rs.open

class properties set by external functions

transaction.begins

Mysql procedure.calls using class properties as parameters - 

commit(or rollback)

rs.populate

class properties.set

properties used by external functions

module terminate - rs.close

并且交易不起作用。我在两周内尝试了所有能想到的方法。
一旦我在交易中声明并关闭了 rs，一切就完美运行了！