如何使用 Racket 宏定义函数？

Question

我正在尝试编写一个宏来定义具有相关函数的特殊数据结构类。

我知道这是可能的；它在核心语言本身中完成了多次。

作为一个具体的例子，我将如何在Scheme本身中定义define-struct宏。它需要创建make-struct、struct-<>等函数。

我尝试使用 define 执行此操作，但是，这仅定义了宏的词法范围内的函数。

如何在宏中实际定义函数？

Answer 1

答案的关键是datum->syntax。基本思想是，您想要获取一些随机数据并将其转换为语法 - 在本例中，将符号转换为标识符。标识符基本上是一个带有一些词汇信息的符号，这些信息（非常粗略地）指示它是如何绑定的。使用datum->syntax你可以做到这一点：它需要一个现有的语法片段，它是从中复制绑定的地方，以及一个数据（这里是一个符号），它是包含的值在语法包装器中。

下面是一个示例，演示了如何使用类似 define-struct 的工具：

#lang scheme
;; implements a defstruct-like macro that uses association lists
(define-syntax (defstruct-lite stx)
  (syntax-case stx ()
    [(defstruct-lite name field ...)
     (let ([make-id
            (lambda (template . ids)
              (let ([str (apply format template (map syntax->datum ids))])
                (datum->syntax stx (string->symbol str))))])
       (with-syntax ([make-name (make-id "make-~a" #'name)]
                     [name?     (make-id "~a?" #'name)]
                     [(arg ...) (generate-temporaries #'(field ...))]
                     [(name-field ...)
                      (map (lambda (f) (make-id "~a-~a" #'name f))
                           (syntax->list #'(field ...)))])
         #'(begin
             (define (make-name arg ...) (list 'name (cons 'field arg) ...))
             (define (name? x) (and (pair? x) (eq? 'name (car x))))
             (define (name-field x)
               (and (name? x) (cdr (assq 'field (cdr x)))))
             ...)))]))

下面是一个使用它的示例：

(defstruct-lite point x y)
(point-y (make-point 1 2))