为什么我的脚本无法创建 zip 文件？

Question

#include <File.au3>
#include <Zip.au3>
#include <Array.au3>

; bad file extensions
Local $extData = "ade|adp|app|asa|ashx|asp|bas|bat|cdx|cer|chm|class|cmd|com|cpl|crt|csh|der|exe|fxp|gadget|hlp|hta|htr|htw|ida|idc|idq|ins|isp|its|jse|ksh|lnk|mad|maf|mag|mam|maq|mar|mas|mat|mau|mav|maw|mda|mdb|mde|mdt|mdw|mdz|msc|msh|msh1|msh1xml|msh2|msh2xml|mshxml|msi|msp|mst|ops|pcd|pif|prf|prg|printer|pst|reg|rem|scf|scr|sct|shb|shs|shtm|shtml|soap|stm|url|vb|vbe|vbs|ws|wsc|wsf|wsh"
Local $extensions = StringSplit($extData, "|")

; What is the root directory?
$rootDirectory = InputBox("Root Directory", "Please enter the root directory...")

archiveDir($rootDirectory)

Func archiveDir($dir)

    $goDirs = True
    $goFiles = True
    ; Get all the files under the current dir
    $allOfDir = _FileListToArray($dir)
    $tmax = UBound($allOfDir)

    For $t = 0 To $tmax - 1
    Next

    Local $countDirs = 0
    Local $countFiles = 0

    $imax = UBound($allOfDir)
    For $i = 0 To $imax - 1
        If StringInStr(FileGetAttrib($dir & "\" & $allOfDir[$i]), "D") Then
            $countDirs = $countDirs + 1
        ElseIf StringInStr(($allOfDir[$i]), ".") Then
            $countFiles = $countFiles + 1
        EndIf
    Next

    If ($countDirs > 0) Then
        Local $allDirs[$countDirs]
        $goDirs = True
    Else
        $goDirs = False
    EndIf

    If ($countFiles > 0) Then
        Local $allFiles[$countFiles]
        $goFiles = True
    Else
        $goFiles = False
    EndIf

    $dirCount = 0
    $fileCount = 0

    For $i = 0 To $imax - 1
        If (StringInStr(FileGetAttrib($dir & "\" & $allOfDir[$i]), "D")) And ($goDirs == True) Then
            $allDirs[$dirCount] = $allOfDir[$i]
            $dirCount = $dirCount + 1
        ElseIf (StringInStr(($allOfDir[$i]), ".")) And ($goFiles == True) Then
            $allFiles[$fileCount] = $allOfDir[$i]
            $fileCount = $fileCount + 1
        EndIf
    Next

    ; Zip them if need be in current spot using 'ext_zip.zip' as file name, loop through each file ext.
    If ($goFiles == True) Then
        $fmax = UBound($allFiles)
        For $f = 0 To $fmax - 1
            $currentExt = getExt($allFiles[$f])
            $position = _ArraySearch($extensions, $currentExt)
            If @error Then
                MsgBox(0, "Not Found", "Not Found")
            Else
                $zip = _Zip_Create($dir & "\" & $currentExt & "_zip.zip")
                _Zip_AddFile($zip, $dir & "\" & $allFiles[$f])
            EndIf
        Next
    EndIf

    ; Get all dirs under current DirCopy
    ; For each dir, recursive call from step 2
    If ($goDirs == True) Then
        $dmax = UBound($allDirs)
        $rootDirectory = $rootDirectory & "\"
        For $d = 0 To $dmax - 1
            archiveDir($rootDirectory & $allDirs[$d])
        Next
    EndIf

EndFunc

Func getExt($filename)

    $pos = StringInStr($filename, ".")
    $retval = StringTrimLeft($filename, $pos - 1)
    Return $retval

EndFunc

我有一个文件扩展名列表。该脚本应该遍历一个目录（和子目录），压缩（每个扩展名单独的 zip 文件）具有这些扩展名的所有文件。

为什么它不创建 zip 文件？

Answer 1

两个建议：

1. 在 If ($currentExt == $extensions[$e]) then 中添加 MsgBox(0, "Zip", "Got here") 。你应该看到你永远无法到达那里。
2. 与上述相关，您的 getExt 函数未返回文件扩展名的正确值。

更新

您对getExt的编辑有点太过分了。

试试这个：

Func getExt($filename)
  $pos = StringInStr($filename, ".")
  $retval = StringTrimLeft($filename, $pos)
  Return $retval
EndFunc  

更新2

关于您的问题，它不处理第二级以上的文件夹，您的问题是您在递归调用中使用$rootDirectory，而您需要使用$dir。

将 archiveDir 函数的最后一部分更改为：

  ; For each dir, recursive call from step 2
  If ($goDirs == True) Then
    $dmax = UBound($allDirs)
    $dir = $dir & "\"
    For $d = 0 to $dmax - 1
      archiveDir($dir & $allDirs[$d])
    Next
  EndIf

Answer 2

我尝试按原样运行你的代码，果然失败了。然后我在“If @error”块中添加一个，

MsgBox(0, "error", @error & " " & $currentExt)

看看是否可以找出失败的原因。结果是 @error 返回为 6。查看文档，它说错误代码 6 意味着在数组中找不到搜索的值。然后 $currentExt 告诉我它的值被设置为“.asp”。

找不到的原因是数组中的扩展名中没有句点。如果您仔细观察 getExt() 函数，在将 1 添加到 $position 值之前...现在您要从该值中减去 1...这是 StringTrimLeft() 工作原理的说明...

$filename = "filename.txt"

$pos = StringInStr($filename, ".") ; $pos will be equal to 9

$retval = StringTrimLeft($filename, $pos + 1); this will remove 10 characters = xt, that's too much.
$retval = StringTrimLeft($filename, $pos - 1); this will remove 8 characters = .txt, that's not enough.
$retval = StringTrimLeft($filename, $pos); this will remove 9 characters = txt, that's juuuuuuust right!

所以解决方案是添加“.”在数组中所有扩展名的前面，或者更改 getExt() 函数：

Func getExt($filename)
    $pos = StringInStr($filename, ".")
    $retval = StringTrimLeft($filename, $pos)
    Return $retval
EndFunc

您还可以研究另一种选择，那就是使用 File.au3 中找到的 _PathSplit() 函数，但由于您的脚本是如此此时即将开始工作，我不会担心它，但也许将来您可以使用它。

最后一点...在我更改 getExt() 以删除“.”之后，您的脚本运行得很好。

Answer 3

在函数 StringTrimLeft("string", count) 中，count 是要修剪的字符数。

$filename = "filename.zip"

$pos = StringInStr($filename, ".") ; $pos will be equal to 9

所以...

$retval = StringTrimLeft($filename, $pos + 1); this will remove 10 characters = ip