如何判断 Perl 代码中的一组括号将充当分组括号还是形成列表？

Question

在 Perl 中，括号用于覆盖优先级（与大多数编程语言一样）以及创建列表。如何判断一对特定的括号是否将被视为分组结构或单元素列表？

例如，我很确定这是一个标量而不是单元素列表：(1 + 1)
但是更复杂的表达式呢？有没有简单的方法可以辨别呢？

Answer 1

这里三个关键原则很有用：

上下文为王。示例 (1 + 1) 的评估取决于上下文。

$x = (1 + 1); # Scalar context. $x will equal 2. Parentheses do nothing here.
@y = (1 + 1); # List context. @y will contain one element: (2).
              # Parens do nothing (see below), aside from following 
              # syntax conventions.

在标量上下文中，不存在列表这样的东西。要看到这一点，请尝试将看似列表的内容分配给标量变量。思考这个问题的方法是关注逗号运算符的行为：在标量上下文中，它计算其左侧参数，丢弃该值，然后计算其右侧参数，并返回该值。在列表上下文中，逗号运算符将两个参数插入到列表中。

@arr  = (12, 34, 56); # Right side returns a list.

$x    = (12, 34, 56); # Right side returns 56. Also, we get warnings
                      # about 12 and 34 being used in void context.

$x = (@arr, 7);       # Right side returns 7. And we get a warning
                      # about using an array in a void context.

括号不会创建列表。逗号运算符创建列表（假设我们处于列表上下文中）。在 Perl 代码中键入列表时，需要括号是出于优先级原因，而不是出于列表创建原因。几个例子：

• 括号不起作用：我们正在评估标量数组
  上下文，因此右侧返回数组大小。

  <前><代码>$x = (@arr);

• 创建包含一个元素的列表不需要括号。

  <前><代码>@arr = 33; # 工作正常，@arr 等于 (33)。

• 但是出于优先顺序的原因，多个项目需要括号。

  <前><代码>@arr = 12, 34, 56; # @arr 等于 (12)。我们收到有关使用的警告
  # 34 和 56 在无效上下文中。

Answer 2

1. 语境。
2. 括号在创建列表时没有您认为的作用。

示例：

$x = 1 + 1;   # $x is 2.
$x = (1 + 1); # $x is 2.
@x = 1 + 1;   # @x is (2).
@x = (1 + 1); # @x is (2).

$x = (1 + 1, 1 + 2); # $x is 3.
@x = (1 + 1, 1 + 2); # @x is (2, 3).

粗略地说，在列表上下文中，逗号运算符分隔列表中的项目；在标量上下文中，逗号运算符是 C“串行逗号”，它计算其左侧和右侧，并返回右侧的值。在标量上下文中，括号对表达式进行分组以覆盖操作顺序，而在列表上下文中，括号所做的...完全相同的事情，真的。它们与分配给数组相关的原因是这样的：

# Comma has precedence below assignment. 
# @a is assigned (1), 2 and 3 are discarded.
@a = 1, 2, 3; 

# @a is (1, 2, 3).
@a = (1, 2, 3);

至于你的问题“它是标量还是单元素列表”，由于上下文的原因，单独询问表达式并不是一个有意义的问题。在列表上下文中，一切都是列表；在标量环境中，什么都不是。

推荐阅读：perlop、perldata，Perl 编程。