F#记录会员评价

Question

为什么每次调用都要评估 tb ？有什么办法让它只评估一次吗？

type test =
  { a: float }
  member x.b =
    printfn "oh no"
    x.a * 2.

let t = { a = 1. }
t.b
t.b

Answer 1

Brian 答案的替代版本最多评估一次 b，但如果从未使用过 B 则根本不会评估它

type Test(a:float) =
    // constructor
    let b = lazy
                 printfn "oh no"
                 a * 2.
    // properties
    member this.A = a
    member this.B = b.Value

Answer 2

它是一种财产；您基本上是在调用 get_b() 成员。

如果您希望构造函数只发生一次效果，您可以使用一个类：

type Test(a:float) =
    // constructor
    let b =   // compute it once, store it in a field in the class
        printfn "oh no"
        a * 2.
    // properties
    member this.A = a
    member this.B = b

Answer 3

为了回应您在 Brian 帖子中的评论，您可以使用可选/命名参数来伪造复制和更新记录表达式。例如：

type Person(?person:Person, ?name, ?age) =

    let getExplicitOrCopiedArg arg argName copy =
        match arg, person with
        | Some(value), _ -> value
        | None, Some(p) -> copy(p)
        | None, None -> nullArg argName

    let name = getExplicitOrCopiedArg name "name" (fun p -> p.Name)
    let age = getExplicitOrCopiedArg age "age" (fun p -> p.Age)

    member x.Name = name
    member x.Age = age

let bill = new Person(name = "Bill", age = 20)
let olderBill = new Person(bill, age = 25)

printfn "Name: %s, Age: %d" bill.Name bill.Age
printfn "Name: %s, Age: %d" olderBill.Name olderBill.Age

Answer 4

之前的回复建议切换到类，而不是使用记录。如果您想保留记录（因为其简单的语法和不变性），您可以采用这种方法：

type test =
    { a : float
      b : float }
    static member initialize (t: test) =
        { t with b = t.a * 2. }

如果 test 的实例是由另一个库（例如来自 Web 的数据提供者）创建的，这非常有用服务或数据库）。使用这种方法时，您必须记住先通过初始化函数传递从该 API 接收到的任何 test 实例，然后再在代码中使用它。