使用 Tcl/Tk 打开存储在 Sqlite 中的 Blob 数据作为文件

Question

我正在使用以下 tcl 代码将文件从桌面存储到 Sqlite 数据库中作为 blob 数据（$fileText 是文本文件的路径）：

sqlite3 db Docs.db
set fileID [open $fileText RDONLY]
fconfigure $fileID -translation binary
set content [read $fileID]
close $fileID
db eval {insert into Document (Doc) VALUES ($content)}
db close

我找到了许多有关如何打开blob 数据读取和写入它，但我找不到任何有关将 blob 数据作为文件打开的资源。例如，如果 $fileText 是 pdf，我如何从 Sqlite 将其打开为 pdf？

Answer 1

当您说“以 PDF 形式打开”时，我假设您的意思是您希望某些外部程序将数据作为文件查看？唯一的方法是：

1. 在 Linux 上使用用户模式文件系统（或操作系统上的等效文件系统）进行一些巧妙的恶作剧，以便可以实际安装数据库，或者
2. 使用以下命令将数据从数据库复制到临时文件中：正确的名称（提示：将其保留为该表中的单独列）。

还有将其全部作为网络服务器呈现，但这实际上是第二个与浏览器混合在一起的；数据仍然被复制。

另一方面，如果您想要做的只是将数据作为可以从 Tcl 读取或写入的流，则 sqlite3 包可以满足您的需要：

dbcmd incrblob ?-readonly? ?db? table column rowid

它返回一个标准通道句柄（尽管不是由操作系统备份的）句柄，因此在使用 exec 进行重定向时要小心）。

---

[编辑]：以下是如何获取数据（当然，用子句替换 ... 以获得正确的行）：

# Open the DB
sqlite3 db Docs.db

# Open the file to write to
set fileID [open $fileText w]
fconfigure $fileID -translation binary

# Write the BLOB
db eval {SELECT Doc FROM Document WHERE ... LIMIT 1} row {
    puts -nonewline $fileID $row(Doc)
}

# We're done!
close $fileID
db close

不要担心 BLOB 的大小； Tcl sqlite3 包有效地传递它。如果您仍然担心，可以使用另一种方法（同样，您需要适当地替换 ...）：

# Open the DB
sqlite3 db Docs.db

# Open the file to write to
set fileOut [open $fileText w]
fconfigure $fileOut -translation binary

# Get the BLOB as a (read-only) channel
set fdBlob [db incrblob -readonly Document Doc ...]
fconfigure $fdBlob -translation binary

# Do the copy 
fcopy $fileOut $fdBlob

# We're done!
close $fdBlob
close $fileOut
db close