如何从 TOleContainer 中提取图元文件？

Question

我有一个带有 TOleContainer 控件的 Delphi (BDS 2006) 应用程序。它内部有一个 OLE 对象，即 MS Office 2003 中的 MS 方程公式（名称“Equation.3”）。

如何从公式图像中提取矢量图元文件，以将其插入网页或其他没有 OLE 支持的文档中？

TOleContainer 内部只有“Equation.3”对象，没有其他可能性。 我尝试使用 .Copy 方法使其通过剪贴板，但它复制了一个空图像。

Answer 1

OLE 容器具有您可以访问的底层 IOLEObject 接口。您可以将其传递给 OLEDraw 函数你自己的画布。您可以使用位图或图元文件画布，然后以您需要的格式保存图像。

OleDraw(OleContainer.OleObjectInterface, DVASPECT_CONTENT, Bmp.Canvas.Handle, R);

{
  DrawOleOnBmp
  ---------------------------------------------------------------------------
  Take a OleObject and draw it to a bitmap canvas.  The bitmap will be sized
  to match the normal size of the OLE Object.
}
procedure DrawOleOnBmp(Ole: IOleObject; Bmp: TBitmap);
var
  ViewObject2: IViewObject2;
  ViewSize: TPoint;
  AdjustedSize: TPoint;

  DC: HDC;
  R: TRect;
begin

  if Succeeded(Ole.QueryInterface(IViewObject2, ViewObject2)) then
  begin
    ViewObject2.GetExtent(DVASPECT_CONTENT, -1, nil, ViewSize);

    DC := GetDC(0);
    AdjustedSize.X := MulDiv(ViewSize.X, GetDeviceCaps(DC, LOGPIXELSX), 2540);
    AdjustedSize.Y := MulDiv(ViewSize.Y, GetDeviceCaps(DC, LOGPIXELSY), 2540);
    ReleaseDC(0, DC);

    Bmp.Height := AdjustedSize.Y;
    Bmp.Width := AdjustedSize.X;

    SetRect(R, 0, 0, Bmp.Width, Bmp.Height);

    OleDraw(Ole, DVASPECT_CONTENT, Bmp.Canvas.Handle, R);
  end
  else
  begin
    raise Exception.Create('Could not get the IViewObject2 interfact on the OleObject');
  end;

end;

Answer 2

当您使用 OleContainer 的 SaveAsDocument 方法时，将创建一个复合文档。该文档将包含一个名称为 #2OlePress000 的 IStream（#2 是字节值 2）。该流的内容是方程的缓存表示形式，用于在未安装方程编辑器的计算机上显示它。

如果您知道该流的格式，也许您可​​以使用它来创建要在网页上显示的图像。