如何在 VBScript 中创建集合对象？

Question

CreateObject 的参数应该是什么？

看这个例子：

Dim a
Set a = CreateObject("Collection") 'getting a runtime error saying ActiveX 
' component can't create object: 'Collection
a.add(CreateObject("Collection"))
a.Items(0).Add(1)
MsgBox(a.Items(0).count)
MsgBox(a.Items(0).Item(0))

Answer 1

for：

dim lista : set lista = CreateObject("Scripting.Dictionary")

你可以这样迭代：

dim key
for each key in lista.keys
    Wscript.Echo key & " = " & lista.item(key)
next

Answer 2

字典怎么样

Set coll = CreateObject("Scripting.Dictionary")
coll.Add 0, "5"
coll.Add 4, "10"
coll.Add "textkey", "15"
MsgBox coll.Count
MsgBox coll.Item(0)
MsgBox coll.Item(4)
wholeColl = ""
for each key in coll.Keys
  wholeColl = wholeColl & key & " = " & coll.Item(key) & ", "
next
MsgBox wholeColl

Answer 3

这是代码，它的功能强大：

Option Explicit

dim list
Set list = CreateObject("System.Collections.ArrayList")
list.Add "Banana"
list.Add "Apple"
list.Add "Pear"

list.Sort
list.Reverse

wscript.echo list.Count                 ' --> 3
wscript.echo list.Item(0)               ' --> Pear
wscript.echo list.IndexOf("Apple", 0)   ' --> 2
wscript.echo join(list.ToArray(), ", ") ' --> Pear, Banana, Apple