将 Fortran int 数组传递给 C++通过调用 C++ Fortran 语言中的函数

Question

我正在尝试在 Fortran 子例程中调用 C++ 函数。这个 C++ 函数应该更新一个整数数组。这是我写的一段不起作用的代码。有什么问题吗？

! Fortran function that calls a C++ function.

subroutine my_function()

      integer(4) ar(*)

      integer(4) get_filled_ar

      ! Need correct syntax here.
      ar = get_filled_ar()
end


// C++ function:

    extern "C" {
        void get_filled_ar(int *ar){
            ar[0] = 1;
            ar[1] = 10;
            ar[3] = 100;
        }
    }

Answer 1

Fortran 2003 提供了一种标准的、独立于平台和编译器的方法来从 Fortran 调用 C，以及使用 C 调用接口的任何语言。还要从 C 调用 Fortran。虽然各个编译器编写者正在逐渐添加 Fortran 2003 功能，并且几乎没有完整的 2003 编译器，但 ISO C 绑定在许多编译器中已经可用了一段时间。 ISO C 绑定比以前的临时技术工作得更好，这些技术有时记录很少，并且在编译器和平台之间存在差异。要从 Fortran 调用 C，您需要编写一个“接口”来告诉 Fortran 编译器它应该使用 C 调用约定和 C 类型。

这是一个例子。正如 Mike 所写，由于 C++ 函数返回 void，因此在 Fortran 中将其视为子例程并调用它。因此不需要给它指定类型。另外，在 Fortran 中的某个地方，您必须为数组保留存储空间——最简单的方法是使用带有维度数值的声明。并且您需要某种语言的主程序。

program test_call_C

use iso_c_binding

implicit none

interface c_interface

   subroutine get_filled_ar (ar) bind (C, name = "get_filled_ar")

   use iso_c_binding

   implicit none

   integer (c_int), intent (out), dimension (*) :: ar

   end subroutine get_filled_ar

end interface c_interface


integer (c_int), dimension (0:3) :: ar

call get_filled_ar (ar)

write (*, *) "Fortran: ar:", ar

stop

end program test_call_C

在 C 中：

void get_filled_ar (
   int ar []
) {

   ar [0] = 1;
   ar [1] = 10;
   ar [2] = 100;

   return;

}

示例命令：

gcc -c get_filled_ar.c
gfortran get_filled_ar.o test_call_C.f90  -o test_call_C.exe
./test_call_C.exe

要调用 C++ 代码，请使用以下命令。 “bind”中指定的名称不需要尾随下划线，因此您的 C++ 代码可以直接运行。

g++ -c cplusplus.cc
gfortran cplusplus.o test_call_C.f90  -o test_call_Cplusplus.exe
./test_call_Cplusplus.exe

Answer 2

这是一个完整的程序，其中包含您的代码，应该可以工作（至少在使用 gcc/gfortran 的 linux 上）。

在 fortran 文件 fortran.f 中，输入：

     IMPLICIT NONE      
     CALL my_function()
     END

! FORTRAN function that calls a C++ function

     subroutine my_function()
! Tell fortran about the C++ function:
       external get_filled_ar

       integer ar(4)

! As the C++ function returns void, call it as a subroutine in
! fortran:
       call get_filled_ar(ar)
! To check it worked, print out the numbers:
       do i = 1,4
          write(*,*) i,"->",ar(i)
       enddo
     end

在 cplusplus.cc 中输入：

extern "C"
{
  void get_filled_ar_(int* ar) // note extra underscore to keep linker happy
  {
    ar[0] = 1;   
    ar[1] = 10;
    ar[3] = 100;
  }    
}

然后构建（在 linux 上使用 gcc/gfortran< /code>，在其他系统上可能有所不同）：

gfortran -c fortran.f
gcc -c cplusplus.cc
gfortran -o program-name fortran.o cplusplus.o