如何在 Perl 中将某些特定的鲤鱼更改为黄花鱼？

Question

我试图捕捉鲤鱼警告：

 carp "$start is > $end" if (warnings::enabled()); ) 

使用 eval {} 但它没有工作，所以我查看了 eval 文档，发现 eval 仅捕获语法错误、运行时错误或执行的 die 语句。

我怎样才能捕捉到鲤鱼警告？

#!/usr/bin/env perl
use warnings;
use strict;
use 5.012;
use List::Util qw(max min);
use Number::Range;

my @array;
my $max = 20;
print "Input (max $max): ";
my $in = <>;

$in =~ s/\s+//g;
$in =~ s/(?<=\d)-/../g;

eval {
    my $range = new Number::Range( $in );
    @array = sort { $a <=> $b } $range->range;
};
if ( $@ =~ /\d+ is > \d+/ ) { die $@ }; # catch the carp-warning doesn't work 

die "Input greater than $max not allowed $!" if defined $max and max( @array ) > $max;
die "Input '0' or less not allowed $!" if min( @array ) < 1;
say "@array";

Answer 1

根据您的评论，我的理解是您希望将 carp 设为致命警告。

如果可以接受将目标包中的所有 carp 警告变成致命错误，那么您可以对 carp 进行猴子补丁。

Carping包：

package Foo;
use Carp;

sub annoying_sub {
    carp "Whine whine whine";
}

主程序：

use Foo;

*Foo::carp = \&Foo::croak;

Foo::annoying_sub();

如果想将monkey补丁限制在动态范围内，可以使用local：

use Foo;

Foo::annoying_sub();  # non-fatal

{   local *Foo::carp = \&Foo::croak;
    Foo::annoying_sub();  # Fatal
}

Answer 2

carp 不会死，只是打印一个警告，所以 eval 或其他什么都没有什么可捕获的。但是，您可以在本地覆盖警告处理程序，以防止警告发送到 stderr：

#!/usr/bin/env perl

use warnings;
use strict;

use Carp;

carp "Oh noes!";

{
    local $SIG{__WARN__} = sub {
        my ($warning) = @_;

        # Replace some warnings:
        if($warning =~ /replaceme/) {
            print STDERR "My new warning.\n";
        }
        else {
            print STDERR $warning;
        }

        # Or do nothing to silence the warning.
    };

    carp "Wh00t!";
    carp "replaceme";
}

carp "Arrgh!";

输出：

Oh noes! at foo.pl line 8
Wh00t! at foo.pl line 25
My new warning.
Arrgh! at foo.pl line 29

在几乎所有情况下，您应该更愿意修复鲤鱼的原因。