流水线函数调用另一个流水线函数

Question

这是一个包含两个管道函数的包：

create or replace type tq84_line as table of varchar2(25);
/

create or replace package tq84_pipelined as

    function more_rows return tq84_line pipelined;
    function go        return tq84_line pipelined;

end tq84_pipelined;
/

Ant 相应的包主体：

create or replace package body tq84_pipelined as

    function more_rows return tq84_line pipelined is
    begin

        pipe row('ist');
        pipe row('Eugen,');

        return;

    end more_rows;

    function go return tq84_line pipelined is
    begin

        pipe row('Mein');
        pipe row('Name');

        /* start */
        for next in (
          select column_value line from table(more_rows)
        ) 
        loop
          pipe row(next.line);
        end loop;
        /* end */

        pipe row('ich');
        pipe row('weiss');
        pipe row('von');
        pipe row('nichts.');

    end go;

end tq84_pipelined;
/

重要的是 go 某种程度 使用 for next in ...< 调用 more_rows /code> /* start */ 和 /* end */

我可以按如下方式使用该包：

select * from table(tq84_pipelined.go);

这一切都很好，但我希望我可以替换通过简单调用 more_rows 即可显示 /* start */ 和 /* end */ 之间的行。

然而，这显然是不可能的，因为它生成了PLS-00221：'MORE_ROWS'不是一个过程或未定义。

所以，我的问题是：真的没有办法缩短循环吗？

编辑

显然，从到目前为止的答案来看，我的问题尚不清楚。

如上所述，该软件包有效。

但我对标记 /* start */ 和 /* end */ 之间的 6 行（即：六行）感到困扰。我想用一行替换它们。但我还没有找到任何方法做到这一点。

Answer 1

管道函数的要点是提供 TABLE() 函数。我认为没有任何办法可以避免它。不幸的是，我们必须将其输出分配给 PL/SQL 变量。我们无法将管道函数分配给像这样的 nt := more_rows; 嵌套表，因为

PLS-00653: aggregate/table functions are not allowed in PL/SQL scope

它必须是 SELECT ... FROM TABLE() 。

我有一个稍微不同的解决方案供您考虑。不知道是否能解决你的根本问题。

create or replace package body tq84_pipelined as 

    function more_rows return tq84_line pipelined is 
    begin 

        pipe row('ist'); 
        pipe row('Eugen,'); 

        return; 

    end more_rows; 

    function go return tq84_line pipelined is 
        nt1 tq84_line;
        nt2 tq84_line;
        nt3 tq84_line;
        nt0 tq84_line;
    begin 

        nt1 := tq84_line('Mein','Name'); 

        select * 
        bulk collect into nt2
        from table(more_rows);

        nt3 := tq84_line('ich','weiss','von','nichts.'); 

        nt0 := nt1 multiset union nt2 multiset union nt3; 

        for i in nt0.first..nt0.last
        loop 
          pipe row(nt0(i)); 
        end loop; 

        return;

    end go; 

end tq84_pipelined; 
/

我确信您已经知道（但为了其他搜索者的利益），Oracle 10g 中引入了用于将集合组合在一起的 MULTISET UNION 语法。

此版本的 GO() 产生与原始实现相同的输出：

SQL> select * from table( tq84_pipelined.go)
  2  /

COLUMN_VALUE
-------------------------
Mein
Name
ist
Eugen,
ich
weiss
von
nichts.

8 rows selected.

SQL>

Answer 2

尝试
从表中选择column_value行(tq84_line.more_rows)
即在查询中包含包名称。