如何使用 Perl 执行多次替换？

Question

我有 Perl 代码：

my $s =  "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog";

我想将每个 + 替换为空格，将 dog 替换为 cat。

我有这个正则表达式：

$s =~ s/\+(.*)dog/ ${1}cat/g;

但是，它只匹配第一次出现的 + 和最后一个 dog。

Answer 1

您可以使用“e”修饰符来执行 s/// 表达式第二部分中的代码。

$s =~ s/(\+)|(dog)/$1 ? ' ' : 'cat'/eg;

如果 $1 为 true，则表示 \+ 匹配，因此它会替换空格；否则它会替换“猫”。

Answer 2

Perl 5.14 及更新版本能够通过非破坏性赋值来链接替换，因此您可以一石三鸟：进行两次全局替换并将结果分配给新变量，而无需修改原始变量。

my $s =  "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog";
my $result = $s =~ s/+/ /gr 
                =~ s/dog/cat/gr; 

将用空格替换所有 + 并将每个 dog 替换为 cat，将结果分配给一个新变量。在单线中。

Answer 3

两个正则表达式可能会让您的生活变得更加轻松：

$s =~ s/\+/ /g;
$s =~ s/dog/cat/g;

下面的匹配“+”，后面跟着一堆东西，后面跟着“dog”。此外，“+”在技术上是一个元字符。

/+(.*)dog/

Answer 4

哈希可以做你想要的：

#!/usr/bin/perl

use strict;
use warnings;

my $s =  "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog";

my %replace = (
    "+" => " ",
    dog => "cat",
);

$s =~ s/([+]|dog)/$replace{$1}/g;

print "$s\n";

在评论中我看到你关心性能，两个正则表达式解决方案性能更高。这是因为任何适用于一个正则表达式的解决方案都需要使用捕获（这会减慢正则表达式的速度）。

以下是基准测试的结果：

eval: The quick brown fox jumps over the lazy cat that is my cat
hash: The quick brown fox jumps over the lazy cat that is my cat
two: The quick brown fox jumps over the lazy cat that is my cat
         Rate hash eval  two
hash  33184/s   -- -29% -80%
eval  46419/s  40%   -- -72%
two  165414/s 398% 256%   --

我使用了以下基准测试：

#!/usr/bin/perl

use strict;
use warnings;

use Benchmark;

my $s =  "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog";

my %replace = (
    "+" => " ",
    dog => "cat",
);

my %subs = (
    hash => sub {
        (my $t = $s) =~ s/([+]|dog)/$replace{$1}/g;
        return $t;
    },
    two => sub {
        (my $t = $s) =~ s/[+]/ /g;
        $t =~ s/dog/cat/g;
        return $t;
    },
    eval => sub {
        (my $t = $s) =~ s/(\+)|(dog)/$1 ? ' ' : 'cat'/eg;
        return $t;
    },
);

for my $k (sort keys %subs) {
    print "$k: ", $subs{$k}(), "\n";
}

Benchmark::cmpthese -1, \%subs;

Answer 5

简单的答案 - 使用 2 行！：

$s =~ s/+/ /g;
$s =~ s/dog/cat/g;

它可能可以通过“非贪婪”匹配在一行中完成，但这应该可以解决问题

Answer 6

如果速度很重要，您可能应该坚持使用两行。但是当我需要一次进行多个替换时，我通常更关心便利性，所以我使用 Chas 建议的哈希值。欧文斯。与两行代码相比，它有两个优点，即它易于修改，并且其行为与预期一致（例如，同时用“cat”替换“dog”，用“dog”替换“cat”时）。

然而，我懒得手动编写正则表达式，而更喜欢用 join 来组装它，并使用 map 来转义东西：

#!/usr/bin/perl

use strict;
use warnings;

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog";

my %replace = (
    "+" => " ",
    dog => "cat",
);

my $regex = join "|", 
    #use quotemeta to escape special characters
    map  { quotemeta } 
    #reverse sort the keys because "ab" =~ /(a|ab)/ returns "a"
    sort { $b cmp $a } keys %replace;

#compiling the regex before using it prevents
#you from having to recompile it each time
$regex = qr/$regex/;

$s =~ s/($regex)/$replace{$1}/g;

print "$s\n";

Answer 7

我知道这是一个旧线程，但这里是 v5.14 之前的 Perls 的一行：

my $s = 'The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog';
$s = do {local $_ = $s; s/\+/ /g; s/dog/cat/g; $_};