匿名方法作为函数结果

Question

我想要做的是将作为函数结果获得的匿名方法分配给相同类型的变量。 Delphi 抱怨无法完成任务。显然，Delphi 我想分配“GetListener”函数而不是同一函数的结果。非常感谢对此的任何帮助。

type
      TPropertyChangedListener = reference to procedure (Sender: TStimulus);

      TMyClass = class
        function GetListener:TPropertyChangedListener
      end;


    ....

    var MyClass: TMyClass;
        Listener: TPropertyChangedListener;
    begin
      MyClass:= TMyClass.create;
      Listener:= MyClass.GetListener;   //  Delphi compile error: E2010 Incompatible types:  TPropertyChangedListener' and 'Procedure of object' 

    end; 

Answer 1

使用以下语法：

  Listener:= MyClass.GetListener();

---

我编写了以下示例来明确 MyClass.GetListener() 和 MyClass.GetListener 分配之间的区别：

type
  TProcRef = reference to procedure(Sender: TObject);
  TFunc = function: TProcRef of object;

  TMyClass = class
    function GetListener: TProcRef;
  end;

function TMyClass.GetListener: TProcRef;
begin
  Result:= procedure(Sender: TObject)
  begin
    Sender.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyClass: TMyClass;
  ProcRef: TProcRef;
  Func: TFunc;

begin
  MyClass:= TMyClass.Create;
// standard syntax
  ProcRef:= MyClass.GetListener();

// also possible syntax
//  Func:= MyClass.GetListener;
//  ProcRef:= Func();

  ProcRef(MyClass);
end;

Answer 2

我发现解决此问题的唯一方法是像这样声明 GetListener：

procedure GetListener(var a: TPropertyChangedListener);

可能有一些语法可以强制编译器考虑函数的结果而不是函数本身，但我找不到任何语法。