在 Perl 中，如何调用名称在字符串中的方法？

Question

我正在尝试编写一些抽象代码，用于在相似对象列表中搜索第一个属性与特定值匹配的对象。为了做到这一点，我需要调用一堆访问器方法并一一检查它们的所有值。我想使用这样的抽象：

sub verify_attribute {
    my ($object, $attribute_method, $wanted_value) = @_;
    if ( call_method($object, $attribute_method) ~~ $wanted_value ) {
        return 1;
    }
    else {
        return;
    }
}

然后我可以循环遍历一个哈希，其键是访问器方法名称，其值是我正在寻找这些属性的值。例如，如果该哈希名为 %wanted，我可能会使用这样的代码来查找我想要的对象：

my $found_object;
FINDOBJ: foreach my $obj (@list_of_objects) {
    foreach my $accessor (keys %wanted) {
        next FINDOBJ unless verify_attribute($obj, $accessor, $wanted{$accessor});
    }
    # All attrs verified
    $found_object = $obj;
    last FINDOBJ;
}

当然，唯一的问题是 call_method 不存在。或者确实如此？如果我有一个包含方法名称的字符串，如何调用该方法？或者有更好的解决方案来解决整个问题吗？

Answer 1

my $found_object;
FINDOBJ: foreach my $obj (@list_of_objects) {
  foreach my $accessor (keys %wanted) {
    next FINDOBJ unless $obj->$accessor() == $wanted{$accessor};
  }
  # All attrs verified
  $found_object = $obj;
  last;
}

是的，您可以通过这种方式调用方法。不涉及字符串（或任何其他）评估。
另外，根据数据的类型，用 eq 或 =~ 替换 ==...

或者，为了获得一些额外的积分，可以这样做功能方式：（all()确实应该是List::Util的一部分！）

use List::Util 'first';

sub all (&@) {
  my $code = shift;
  $code->($_) || return 0 for @_;
  return 1;
}

my $match = first {
                    my $obj = $_;
                    all { $obj->$_ == $attrs{$_} }
                      keys %wanted
                  } @list_of_objects;

更新：诚然，第一个解决方案是不太混乱的解决方案，所以它是更好的选择。但作为回答问题的人，你也添加了一点糖，让自己变得有趣！ ;-)

Answer 2

函数式方式很酷，但对于像我这样的傻瓜来说评估规则：

test.pl

#!/usr/bin/perl -l
use F;
my $f = F->new();

my $fun = 'lol'; # method of F

eval '$f->'.$fun.'() '; # call method of F, which name is in $fun var

F.pm

package F;

sub new
{
    bless {};
}


sub lol
{
    print "LoL";
}
1;

[root@ALT-24 root]# perl test.pl

LoL