Perl 子例程可以返回数据但继续处理吗？

Question

有没有办法让子程序在处理的同时发送回数据？例如（此示例仅用于说明）- 子例程读取文件。当它读取文件时，如果满足某些条件，则“返回”该行并继续处理。我知道有些人会回答——你为什么要这么做？为什么你不只是......？，但我真的很想知道这是否可能。

Answer 1

实现此类功能的常见方法是使用回调函数：

{
    open my $log, '>', 'logfile' or die $!;
    sub log_line {print $log @_}
}

sub process_file {
    my ($filename, $callback) = @_;
    open my $file, '<', $filename or die $!;
    local $_;
    while (<$file>) {
        if (/some condition/) {
             $callback->($_)
        }
        # whatever other processing you need ....
    }
}

process_file 'myfile.txt', \&log_line;

或者甚至不命名回调：

process_file 'myfile.txt', sub {print STDERR @_};

Answer 2

某些语言使用 “生成器” 或 "协程"，但 Perl 没有。上面链接的生成器页面包含 Python、C# 和 Ruby（以及其他语言）的示例。

Answer 3

Coro 模块看起来对此很有用问题，尽管我不知道它是如何工作的，也不知道它是否按照其广告宣传的那样工作。

Answer 4

在 Perl 中执行此操作的最简单方法可能是使用迭代器类型的解决方案。例如，这里我们有一个子例程，它形成一个 闭包 在文件句柄上：

open my $fh, '<', 'some_file.txt' or die $!;
my $iter = sub { 
    while( my $line = <$fh> ) { 
        return $line if $line =~ /foo/;
    }

    return;
}

子程序遍历各行，直到找到与模式 /foo/ 匹配的行，然后返回它，否则不返回任何内容。 （标量上下文中的undef。）因为文件句柄$fh是在子范围之外定义的，所以它在调用之间仍然驻留在内存中。最重要的是，它的状态，包括文件中当前的查找位置，都会被保留。因此，每次调用子例程都会从上次停止的位置继续读取文件。

要使用迭代器：

while( defined( my $next_line = $iter->() ) ) { 
    # do something with each line here
}

Answer 5

如果您确实想这样做，可以使用线程。一种选择是分叉一个单独的线程来读取文件，当它找到某一行时，将其放置在线程之间共享的数组中。然后另一个线程可以获取找到的行并处理它们。下面是一个读取文件、在文件行中查找“X”并在找到时执行操作的示例。

use strict;
use threads;
use threads::shared;

my @ary : shared;

my $thr = threads->create('file_reader');

while(1){
    my ($value);
    {
        lock(@ary);
        if ($#ary > -1){
            $value = shift(@ary);
            print "Found a line to process:  $value\n";
        }
        else{
            print "no more lines to process...\n";
        }            
    }

    sleep(1);
    #process $value
}


sub file_reader{

            #File input
    open(INPUT, "<test.txt");
    while(<INPUT>){
        my($line) = $_;
        chomp($line);

        print "reading $line\n";

        if ($line =~ /X/){
            print "pushing $line\n";
            lock(@ary);
            push @ary, $line;
        }
        sleep(4)
    }
    close(INPUT);
}

尝试将此代码作为 test.txt 文件：

line 1
line 2X
line 3
line 4X
line 5
line 6
line 7X
line 8
line 9
line 10
line 11
line 12X

Answer 6

如果你的语言支持闭包，你也许可以这样做：

顺便说一句，该函数不会继续处理文件，它会在你调用它时运行，所以它可能不是你需要的。

（这是类似javascript的伪代码）

function fileReader (filename) {
    var  file = open(filename);

    return function () {
        while (s = file.read()) {
            if (condition) {
                return line;
            }
        }
        return null;
   }     
}

a = fileReader("myfile");
line1 = a();
line2 = a();
line3 = a();

Answer 7

递归子怎么样？重新打开现有文件句柄不会重置输入行号，因此它会从中断处继续。

下面是一个示例，其中 process_file 子例程打印出包含 foo 的以空行分隔的 "\n\n" 段落。

sub process_file {

    my ($fileHandle) = @_;
    my $paragraph;

    while ( defined(my $line = <$fileHandle>) and not eof(<$fileHandle>) ) {

        $paragraph .= $line;
        last unless length($line);
    }

    print $paragraph if $paragraph =~ /foo/;
    goto &process_file unless eof($fileHandle);  
       # goto optimizes the tail recursion and prevents a stack overflow
       # redo unless eof($fileHandle); would also work
}

open my $fileHandle, '<', 'file.txt';
process_file($fileHandle);