是否可以将一个对象的实例化限制为 VB.NET 中的另一个（父）对象？

Question

VB 2008 .NET 3.5

假设我们有两个类，Order 和 OrderItem，它们代表某种类型的在线订购系统。 OrderItem 表示订单中的单个行项目。一个Order可以包含多个OrderItem，以List(of OrderItem)的形式。

Public Class Order
    Public Property MyOrderItems() as List(of OrderItem)
    End Property
End Class

没有订单就不应存在 OrderItem，这是有道理的。换句话说，OrderItem 类不应该能够自行实例化，它应该依赖于 Order 类来包含它并实例化它。但是，OrderItem 的范围应该是公共的，以便其他对象可以访问它的属性。因此，OrderItem 的要求是：

1. 只能由 Order 类实例化。

2. 必须是公共的，以便任何其他对象都可以通过 Order 对象访问它的属性/方法。例如 Order.OrderItem(0).ProductID。

3. OrderItem 应该能够传递给对其进行操作的其他子程序/函数。

我怎样才能实现这些目标？有更好的方法吗？

Answer 1

您可以创建一个带有 Order 项目的 OrderItem 构造函数。

在此构造函数中，您可以将 OrderItem 添加到 Order.MyOrderItems 集合中。

这将满足您的要求。

Public Class OrderItem
    Public Sub New(ByRef myOrder As Order)
        myOrder.MyOrderItems.Add(Me)
    End Sub
End Class

1. 您只能通过向其传递有效的 Order 对象来实例化 OrderItem。
2. 仍然是公开的，可以根据需要调用 (Order.OrderItem(0).ProductID)。
3. OrderItem 可以传递给其他子函数和函数。

Answer 2

执行此操作的标准方法是将 OrderItem 公开为接口，然后在 Order 类内的私有类中实现它。 OrderItem 类只能在 Order 类内部实例化，但可以通过公共 IOrderItem 接口暴露给外部。就像这样：

Public Interface IOrderItem
    ReadOnly Property ItemCode() As Integer
    ReadOnly Property NumberOfItems() As Integer
    ReadOnly Property Description() As String
End Interface

Public Class Order

    Private m_Items As List(Of IOrderItem)

    Public ReadOnly Property Items() As List(Of IOrderItem)
        Get
            Return m_Items
        End Get
    End Property

    Private Class OrderItem
        Implements IOrderItem

        Private m_Code As Integer
        Private m_NumItems As Integer
        Private m_Description As String

        Public Sub New(ByVal code As Integer, ByVal numItems As Integer, ByVal desc As String)
            m_Code = code
            m_NumItems = numItems
            m_Description = desc
        End Sub

        Public ReadOnly Property Description() As String Implements IOrderItem.Description
            Get
                Return m_Description
            End Get
        End Property

        Public ReadOnly Property ItemCode() As Integer Implements IOrderItem.ItemCode
            Get
                Return m_Code
            End Get
        End Property

        Public ReadOnly Property NumberOfItems() As Integer Implements IOrderItem.NumberOfItems
            Get
                Return m_NumItems
            End Get
        End Property
    End Class
End Class

Answer 3

OrderItem 的构造函数应该是 friend （只能访问 Order） - 我说 friend 因为使用 朋友，您可以限制 OrderItem 构造函数对同一程序集中的类的可见性。 注意：此解决方案意味着 Order 和 OrderItem 位于一个库/程序集中，而您正尝试从另一程序集中使用它们 - 否则 friend 保护将不起作用。

创建 OrderItem 对象的责任应该只属于 Order：

构建一个类似于 Order 类的方法：Public Function CreateOrderItem(whateverParametersYouNeed) ) 作为 OrderItem，在内部实例化一个新的 OrderItem，将其添加到 OrderItem 列表中并返回对新创建的项目的引用。

然后，您可以使用此 OrderItem 执行任何您想要的操作 - 它将始终属于 Order 的列表。