在as3中禁用重复键盘按下事件

Question

现在我试图让键盘事件停止重复。

我的想法是当按键被按下时有一个真假条件，这样如果按键已经按下，它就不会重复。

//Mouse Event Over
keyCButton.addEventListener(MouseEvent.MOUSE_OVER, function(){gotoAndStop(2)});
//Variable
var Qkey:uint = 81;
//Key Down Event
stage.addEventListener(KeyboardEvent.KEY_DOWN, keydown);
var soundplayed = false;
function keydown(event:KeyboardEvent){
    if (event.keyCode==Qkey) {
        this.soundplayed=true;
    }
}

if (this.soundplayed==false){
    gotoAndPlay(3);
}

//Key Up Event
stage.addEventListener(KeyboardEvent.KEY_UP, keyup);

function keyup(event:KeyboardEvent){
    this.soundplayed=false;
    gotoAndStop(1);
}

这样做会使按键一遍又一遍地循环，而无需键盘事件 我想我需要在“if (this.soundplayed==true)”中添加一个“&& keyDown...”，但我不知道如何在不出现错误的情况下做到这一点，

这是我正在尝试的键盘手修复http://soulseekrecords.org/psysci/animation/piano.html

Answer 1

这是 Kishi 已经建议的另一种（可能更通用）的编写方式：

stage.addEventListener(KeyboardEvent.KEY_DOWN,keyDown);
stage.addEventListener(KeyboardEvent.KEY_UP,keyUp);

var downKeys:Dictionary = new Dictionary();

function keyDown(e:KeyboardEvent):void {
    if(!downKeys[e.keyCode]) {
        downKeys[e.keyCode] = true;
        processKeyDown(e);
    }
}

function keyUp(e:KeyboardEvent):void {
    delete downKeys[e.keyCode];
}

function processKeyDown(e:KeyboardEvent):void {
    trace(e.keyCode);
}

将调用 processKeyDown 函数，就像禁用了 keydown 重复一样。如果您需要在按键按下时执行某些操作，请将该代码放入 keyUp 函数中，或者调用像 processKeyDown 一样定义的 processKeyUp 函数。

Answer 2

我不确定你在这些框架上做什么。
这是完整的代码吗？

不管怎样，你应该尝试这样的事情：

// Mouse Events
this.keyCButton.addEventListener(MouseEvent.MOUSE_OVER, function():void{ gotoAndStop(2) });

// Variables
var Qkey:uint = 81;
var soundplayed = false;

// Keyboard events
this.stage.addEventListener(KeyboardEvent.KEY_DOWN, keydown);
this.stage.addEventListener(KeyboardEvent.KEY_UP, keyup);

// Event listeners
function keydown(event:KeyboardEvent){
    if (event.keyCode == Qkey && !this.soundplayed) {
        this.soundplayed = true;
        this.gotoAndPlay(3);
    }
}

function keyup(event:KeyboardEvent){
    this.soundplayed = false;
    this.gotoAndStop(1);
}

注意 keydown 事件监听器现在将执行一次 - 我的意思是..至少 if 分支 - 作为 soundplayed 变量用作锁定机构。
它只会在执行keyup后再次执行（this.soundplayed = false）。