如何将汉字一一拆分？

Question

如果名字和姓氏之间没有特殊字符（例如空格、:等）。

那么下面如何拆分汉字呢。

use strict; 
use warnings; 
use Data::Dumper;  

my $fh = \*DATA;  
my $fname; # 小三； 
my $lname; # 张 ；
while(my $name = <$fh>)
{

    $name =~ ??? ;
    print $fname"/n";
    print $lname;

}

__DATA__  
张小三

输出

小三
张

[更新]

WinXP。使用ActivePerl5.10.1。

Answer 1

您遇到问题是因为您忽略了在输入期间将二进制数据解码为 Perl 字符串并在输出期间将 Perl 字符串编码为二进制数据。其原因是正则表达式及其朋友 split 在 Perl 字符串上正常工作。

(?<=.) 表示“第一个字符之后”。因此，该程序无法在复姓/复合姓氏上正常工作；请记住，它们很罕见，但确实存在。为了始终正确地将名字拆分为姓氏和名字部分，您需要使用包含姓氏的字典。

Linux 版本：

use strict;
use warnings;
use Encode qw(decode encode);

while (my $full_name = <DATA>) {
    $full_name = decode('UTF-8', $full_name);
    chomp $full_name;
    my ($family_name, $given_name) = split(/(?<=.)/, $full_name, 2);
    print encode('UTF-8',
        sprintf('The full name is %s, the family name is %s, the given name is %s.', $full_name, $family_name, $given_name)
    );

}

__DATA__
张小三

输出：

The full name is 张小三, the family name is 张, the given name is 小三.

Windows 版本：

use strict;
use warnings;
use Encode qw(decode encode);
use Encode::HanExtra qw();

while (my $full_name = <DATA>) {
    $full_name = decode('GB18030', $full_name);
    chomp $full_name;
    my ($family_name, $given_name) = split(/(?<=.)/, $full_name, 2);
    print encode('GB18030',
        sprintf('The full name is %s, the family name is %s, the given name is %s.', $full_name, $family_name, $given_name)
    );

}

__DATA__
张小三

输出：

The full name is 张小三, the family name is 张, the given name is 小三.

Answer 2

您需要某种启发式方法来区分名字和姓氏。这是一些工作代码，假设姓氏（姓氏）是一个字符（第一个字符），所有其余字符（至少一个）都属于名字（给定名称）：

编辑：更改程序以忽略无效行而不是快死了。

use strict;
use utf8;

binmode STDOUT, ":utf8";

while (my $name = <DATA>) {
    my ($lname, $fname) = $name =~ /^(\p{Han})(\p{Han}+)$/ or next;
    print "First name: $fname\nLast name: $lname\n";
}

__DATA__  
张小三

当我从命令行运行该程序时，我得到以下输出：

First name: 小三
Last name: 张

Answer 3

这会分割字符并将它们分配给 $fname 和 $lname。

my ($fname, $lname) = $name =~ m/ ( \X ) /gx;

虽然我认为你的例子和你的问题并不真正匹配（姓氏有两个字符。