使用 LINQ Select 插入 XElement？

Question

我有一个 xml 源代码片段，我想在其中插入多个元素，这些元素是根据原始 xml 中找到的某些值创建的。

目前，我有一个子程序可以为我执行此操作：

<Extension()>
Public Sub AddElements(ByVal xml As XElement, ByVal elementList As IEnumerable(Of XElement))

    For Each e In elementList
        xml.Add(e)
    Next

End Sub

这在例程中被调用，如下所示：

Dim myElement = New XElement("NewElements")

myElement.AddElements(
     xml.Descendants("TheElements").
     Where(Function(e) e.Attribute("FilterElement") IsNot Nothing).
     Select(Function(e) New XElement("NewElement", New XAttribute("Text", e.Attribute("FilterElement").Value))))

是否可以使用 Linq 语法重新编写此代码，这样我就不需要调用 Sub AddElements，但可以内联完成所有操作

Many Thx

Simon

Answer 1

当然：

Dim outputxml = 
   New XElement("NewElements",
      xml.Descendants("TheElements").
      Where(Function(e) e.Attribute("FilterElement") IsNot Nothing).
      Select(Function(e) _
         New XElement("NewElement", 
            New XAttribute("Text",e.Attribute("FilterElement").Value)
         )
      )
   )

XElement 和 XAttribute 具有构造函数（除了元素或属性名称之外）接受任意数量的对象（它们本身可以是查询或其他 IEnumerables） ）。传递给构造函数的任何内容都会作为内容添加。

您可能还想研究 XML 文字，这使得它更具可读性，但本质上做的是同样的事情。

使用 XML 文字，它看起来像这样：

dim outputxml = 
   <NewElements><%=   
      From e In xml...<TheElements> 
      Where e.@FilterElement IsNot Nothing 
      Select <NewElement Text=<%= e.@FilterElement %>/>
   %></NewElements>
' you can embed names and attribute values too

• < %= %> 在 XML 中嵌入 VB 表达式的值
• xml... 选择名为 elemname
• 'elem.@attrname` 的 xml 后代获取属性的值

这几乎是 XQuery ;-)。