访问 _CopyArray 过程

Question

有没有办法访问（和调用）像 _CopyArray 这样在单元系统的接口中定义的过程？

注意：我正在尝试创建一个例程来深度克隆任何动态数组，并且不使用 Delphi 2010（使用 Delphi 2007）。

我试图在不使用 Copy 的情况下解决这个问题的原因是，我只有一个动态数组所在的指针（即指针）加上一个 typeinfo 引用。我无法调用 Copy 函数，因为它隐式需要填写类型信息。

解决方案： 您需要通过将 _ 替换为 @ 并将其范围限定为 system 来引用它。

procedure CopyArray( dest, source, typeInfo: Pointer; cnt: Integer );
asm
    PUSH    dword ptr [EBP+8]
    CALL    system.@CopyArray
end;

type
    PObject = ^TObject;

function TMessageRTTI.CloneDynArray( Source: Pointer; T: TTypeRecord ): Pointer;
var
    TypeInfo: TTypeRecord;
    L:        Integer;
    PObj:     PObject;
    PArr:     PPointer;
begin
    Assert( T.TypeKind = tkDynArray );

    // set size of array
    Result := nil;
    L := Length( TIntegerDynArray( Source ) );
    if L = 0 then Exit;
    DynArraySetLength( Result, T.TypeInfo, 1, @L );

    if Assigned( T.TypeData^.elType ) then TypeInfo := ByTypeInfo( T.TypeData^.elType^ ) else TypeInfo := nil;
    if Assigned( TypeInfo ) then begin
        case TypeInfo.TypeKind of
            tkClass: begin
                PObj := Result;
                while L > 0 do begin
                    PObj^ := CloneObject( PObject( Source )^ );
                    Inc( PObject( Source ) );
                    Inc( PObj );
                    Dec( L );
                end;
            end;
            tkDynArray: begin
                PArr := Result;
                while L > 0 do begin
                    PArr^ := CloneDynArray( PPointer( Source )^, TypeInfo );
                    Inc( PPointer( Source ) );
                    Inc( PArr );
                    Dec( L );
                end;
            end;
            else CopyArray( Result, Source, TypeInfo.TypeInfo, L );
        end;
    end else begin
        // We can simply clone the data
        Move( Source^, Result^, L * T.ElementSize );
    end;
end;

Answer 1

正如 Serg 和 Andreas 所说，_ 例程都使用编译器魔法来提供功能，因此您应该使用 Copy 而不是 _CopyArray，is 而不是_IsClass 等。

要直接回答您的问题，不，没有办法从其他单元中的 Delphi 代码调用这些例程。 RTL 的 makefile 在编译 System.pas 和 SysInit.pas 时会传递一个未记录的编译器开关，该开关告诉编译器将任何前导 _ 字符转换为 @。例如，_CopyArray 变为 @CopyArray。您可以使用 BASM（汇编）块来调用它，但仅此而已。

Answer 2

Andreas Rejbrand 的评论实际上是一个答案 - 当您复制复杂数组时，会自动调用 _CopyArray 过程。例如，在 _CopyArray 中设置断点并运行以下代码（应使用 debug .dcu 进行编译以激活断点）：

procedure TForm1.Button4Click(Sender: TObject);
type
  TArr2D = array of TBytes;

var
  A, B: TArr2D;

begin
  A:= TArr2D.Create(TBytes.Create(1, 2, 3), TBytes.Create(4, 5));
  B:= Copy(A);
  Button4.Caption:= IntToStr(B[1, 1]);
end;