如何在 Erlang 中使进程并行运行？

Question

startTrains() ->
    TotalDist = 100,
    Trains = [trainA,trainB ],
    PID = spawn(fun() -> 
            train(1,length(Trains)) end),
    [ PID ! {self(),TrainData,TotalDist} || TrainData <- Trains],
    receive
    {_From, Mesg} ->
        error_logger:info_msg("~n Mesg ~p ~n",[Mesg])
            after 10500 ->
        refresh
    end.

所以，我创建了两个名为trainA、trainB的进程。我想将这些进程增加 5，直到达到 100。我做了不同的进程，使每个火车（进程）并行增加其位置。但我很惊讶地顺序得到输出，即进程 trainA 结束，然后进程 trainB 开始。但我想同时增加自己。 我想运行这样的进程，

---

trainA 10 trainB 0
trainA 15 trainB 5
....
trainA 100 trainB 100 

---

但我得到了

---

trainA 0
....
trainA 90
trainA 95
trainA 100
trainA ends

trainB 0
trainB 5
trainB 10
.....
trainB 100

---

如何使进程并行/同时运行？希望你能收到我的问题。请帮我。

Answer 1

您仅生成一个由函数 train/2 初始化的进程。您提供的代码不完整，所以我只能猜测，但我认为您的代码是错误的，因为您只有一个火车流程。寻求灵感：

-module(trains).

-export([startTrains/0]).

startTrains() ->
  TotalDist = 100,
  Names = [trainA,trainB ],
  Self = self(),
  Trains = [spawn_link(fun() -> 
          train(Name, Self) end) || Name <- Names],
  [ Train ! {start, Self, 0, TotalDist} || Train <- Trains],
  ok = collectResults(Names).

collectResults([]) -> ok;
collectResults(Trains) ->
  receive
    {stop, Name, Pos, Length} ->
      io:format("~p stops at ~p (~p)~n", [Name, Pos, Length]),
      collectResults(Trains -- [Name]);
    Msg ->
      io:format("Supervisor received unexpected message ~p~n", [Msg]),
      collectResults(Trains)
  after 10500 -> timeout
  end.

train(Name, Sup) ->
  receive
    {start, Sup, Pos, Length} -> run_train(Name, Sup, Pos, Length);
    Msg ->
      io:format("~p received unexpected message ~p~n", [Name, Msg]),
      train(Name, Sup)
  end.

run_train(Name, Sup, Pos, Length)
  when Pos < Length ->
    receive after 500 ->
        NewPos = Pos + 5,
        io:format("~p ~p~n", [Name, Pos]),
        run_train(Name, Sup, NewPos, Length)
    end;
run_train(Name, Sup, Pos, Length) ->
  Sup ! {stop, Name, Pos, Length}.

但如果我认真思考的话，我应该考虑 gen_fsm 和 OTP 原则。但在当前阶段，请继续使用 erlang 原语，以便首先获得更好的感觉。