如何在 Perl 中提取匹配大括号之间的字符串？

Question

我的输入文件如下：

HEADER 
{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}

{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}

{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}

{ABC|*|XYZ:ghi:jkl {JKL 0 372 0} {{Points {}}}}

{ABC|*|XYZ:mno:pqr {GHI 0 34 0} {{Points {}}}}

{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }
TRAILER

我想将文件提取到数组中，如下所示：

$array[0] = "{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}"

$array[1] = "{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}"

$array[2] = "{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}"

..
..

$array[5] = "{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }"

这意味着，我需要将第一个左大括号与其右大括号匹配，并提取之间的字符串。

我已检查以下链接，但这不适用于我的问题。 正则表达式获取字符串在大括号之间“{我想要大括号之间的内容}”

我正在尝试，但如果有人可以用他们的专业知识帮助我，那真的会很有帮助......

谢谢 斯里...

Answer 1

这当然可以通过正则表达式来完成，至少在现代版本的 Perl 中：

my @array = $str =~ /( \{ (?: [^{}]* | (?0) )* \} )/xg;

print join "\n" => @array;

正则表达式匹配包含非大括号字符的大括号块，或递归到其自身（匹配嵌套大括号）

编辑：上面的代码适用于 Perl 5.10+ ，对于早期版本，递归有点冗长：

my $re; $re = qr/ \{ (?: [^{}]* | (??{$re}) )* \} /x;

my @array = $str =~ /$re/xg;

Answer 2

使用 Text::Balanced

Answer 3

我同意 ysth 的建议，使用 Text::Balanced 模块。几行就可以让您上路。

use strict;
use warnings;
use Text::Balanced qw/extract_multiple extract_bracketed/;

my $file;
open my $fileHandle, '<', 'file.txt';

{ 
  local $/ = undef; # or use File::Slurp
  $file = <$fileHandle>;
}

close $fileHandle;

my @array = extract_multiple(
                               $file,
                               [ sub{extract_bracketed($_[0], '{}')},],
                               undef,
                               1
                            );

print $_,"\n" foreach @array;

---

输出

{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}
{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}
{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}
{ABC|*|XYZ:ghi:jkl {JKL 0 372 0} {{Points {}}}}
{ABC|*|XYZ:mno:pqr {GHI 0 34 0} {{Points {}}}}
{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }

Answer 4

你总是可以计算大括号的数量：

my $depth = 0;
my $out = "";
my @list=();
foreach my $fr (split(/([{}])/,$data)) {
    $out .= $fr;
    if($fr eq '{') {
        $depth ++;
    }
    elsif($fr eq '}') {
        $depth --;
        if($depth ==0) {
            $out =~ s/^.*?({.*}).*$/$1/s; # trim
            push @list, $out;
            $out = "";
        }
    }
}
print join("\n==================\n",@list);

这是古老的、简单的 Perl 风格（而且可能很丑）。

Answer 5

我不认为你想在这里使用纯正则表达式（恕我直言，这甚至可能无法使用正则表达式进行解析）。

相反，构建一个小型解析器，类似于此处所示的内容： http://www.perlmonks.org/ ?node_id=308039
（参见 shotgunefx (Parson) 于 2003 年 11 月 18 日 18:29 UTC 的回答）

更新 似乎可以使用正则表达式来实现 - 我在 掌握正则表达式（可以在 Google 图书上找到，因此如果您没有这本书，可以在 google 上搜索 - 请参阅第 5 章，“匹配括号的平衡组”部分）

Answer 6

对于这种类型的解析，使用状态机比使用正则表达式要好得多。

Answer 7

正则表达式实际上对于匹配大括号来说非常糟糕。根据您想要深入的程度，您可以为 解析::RecDescent。或者，如果您只想获取块，请搜索打开的“{”标记和关闭的“}”，然后记录在任何给定时间有多少个打开的块。