在 VS2010 中，有没有办法知道给定的 w3wp.exe 正在服务哪个应用程序池，然后决定将调试器附加到？

Question

因此，我正在调试一些在单独的应用程序池中本地运行的网站（一个来自主干，一个来自分支）。我在两个 VS 实例中打开了主干和分支解决方案。我想在一个中调试主干，在另一个中调试分支。我想知道是否有一种方法可以知道每个 w3wp.exe 正在服务哪个应用程序池，以便在附加调试器时知道哪个是哪个应用程序池。

更新：这样做的目的是在 VS 中编写一个宏，然后让我有一个按钮（每个有趣的应用程序池），可以单击该按钮来附加调试器。因此解决方案最好不涉及其他程序。

Update2：这是在 Windows 7 上针对 IIS7 的。

Answer 1

下面是我的核心宏。编写一些单行子程序来调用它，例如 AttachToW3wp("DefaultAppPool") 命名您感兴趣的每个应用程序池，并为它们制作按钮和热键。

    Private Sub AttachToW3wp(ByVal appPoolName As String)
    Const processName As String = "w3wp.exe"
    Dim userName As String = String.Format("IIS APPPOOL\{0}", appPoolName)

    Try
        Dim debugger As EnvDTE90.Debugger3 = CType(DTE.Debugger, EnvDTE90.Debugger3)
        'debugger.DetachAll()

        Dim transport As EnvDTE80.Transport = debugger.Transports.Item("Default")
        Dim qualifier As String = Environment.MachineName '= My.Computer.Name
        Dim engines(3) As EnvDTE80.Engine
        engines(0) = transport.Engines.Item("Managed")
        engines(1) = transport.Engines.Item("Script")
        engines(2) = transport.Engines.Item("T-SQL")

        Dim successMessage As String = String.Empty
        For Each process As EnvDTE80.Process2 In debugger.GetProcesses(transport, qualifier)
            With process
                Dim fi As New System.IO.FileInfo(.Name)
                If fi.Name = processName AndAlso (String.Compare(.UserName, 0, userName, 0, Len(userName), True) = 0) Then
                    If .IsBeingDebugged Then Throw New Exception(String.Format("{0} {1} is already attached to a debugger.", processName, userName))

                    process.Attach2(engines)
                    successMessage = String.Format("Attached to {0} for {1} ({2})", processName, userName, .ProcessID)

                    Exit For
                End If
            End With
        Next

        If successMessage = String.Empty Then
            Throw New Exception(String.Format("{0} {1} not found.", processName, userName))
        Else
            Trace.WriteLine(successMessage)
        End If

    Catch ex As System.Exception
        MsgBox(ex.Message)
    End Try
End Sub

Answer 2

另一种选择是 WADA - W3WP Advanced Attacher视觉工作室画廊。我通过在扩展管理器的在线图库中搜索“附加工作人员”找到了它。

Answer 3

查看此问题的答案。您可以从命令窗口运行内置脚本来执行此操作。

Answer 4

如果您可以在每个分支上执行请求，则可以使用类似 Process Explorer< /a> 或任务管理器来查看哪个 ID 可能是哪个 ID，因为假设您可以实现这种分离，则可能会占用当前正在处理请求的 CPU 周期。

Answer 5

您可以使用任务管理器查看进程运行时的用户名（一般与应用程序池名称相同）和进程ID，但是您必须在任务管理器中打开这些列，同时还要打开进程名称必须与应用程序池相同（据我所知，这是默认值）。
另请注意，此页面上列出的所有方法可能只显示当前正在运行的进程，这意味着如果您的特定进程由于空闲时间而关闭，您必须首先使用该站点才能将该进程显示在列表中，在您的情况下，这意味着您应该首先访问所有站点以确保与它们关联的进程正在运行。