sed/awk 或其他：一行将数字增加 1 并保持空格字符

Question

编辑：我事先不知道我的数字将在哪一“列”，我想要一句台词。显然 sed 不做算术，所以也许有一个基于 awk 的单行解决方案？

我有一个字符串：（注意间距）

eh oh    37

，我希望它变成：（

eh oh    36

所以我想保持间距）

使用 awk 我不知道如何做到这一点，到目前为止我有：

echo "eh oh   37" | awk '$3>=0&&$3<=99 {$3--} {print}'

但这给出：（

eh oh 36

空格字符丢失，因为字段分隔符是“”）

有没有办法询问awk类似“使用完全相同的字段分隔符打印输出因为输入有“？

然后我尝试了其他方法，使用 awk 的 sub(..,..) 方法：

' sub(/[0-9][0-9]/, ...) {print}'

但还没有雪茄：我不知道如何引用正则表达式并在第二个参数中对其进行算术运算（我现在用“...”留下）。

然后我尝试使用 sed，但在此之后卡住了：

echo "eh oh   37" | sed -e 's/\([0-9][0-9]\)/.../' 

Can I do maths from sed using a reference to thematchingdigits and have the output notmodify the number of spacecharacter?

请注意，它与我有关 Emacs 的问题以及如何将其应用于某些（大）Emacs 区域（使用 Emacs 的 shell-command-on-region 的替换区域）相关，但这不是一个相同的问题：这一篇专门讨论如何在使用 awk/sed/etc 时“保留空格”。

Answer 1

这是ghostdog74答案的一个变体，它不需要将数字锚定在字符串的末尾。这是通过使用 match 来完成的，而不是依赖于特定位置的数字。

这会将第一个数字替换为其值减一：

$ echo "eh oh    37      aaa     22    bb" | awk '{n = substr($0, match($0, /[0-9]+/), RLENGTH) - 1; sub(/[0-9]+/, n); print }'
eh oh    36      aaa     22    bb

使用 gsub 代替 sub 会将“37”和“22”替换为“36”。如果线路上只有一个号码，则使用哪一个都没有关系。不过，通过这种方式，它将处理带有尾随空格的数字以及可能存在的其他非数字字符（在一些空格之后）。

如果您有 gawk，您可以像这样使用 gensub 来挑选字符串中的任意数字（只需设置 which 的值）：

$ echo "eh oh    37      aaa     22    bb    19" |
    awk -v which=2 'BEGIN { regex = "([0-9]+)\\>[^0-9]*";
        for (i = 1; i < which; i++) {regex = regex"([0-9]+)\\>[^0-9]*"}}
        { match($0, regex, a);
        n = a[which] - 1;                    # do the math
        print gensub(/[0-9]+/, n, which) }'
eh oh    37      aaa     21    bb    19

第二个 (which=2) 数字从 22 变为 21。嵌入的空格被保留。

它分为多行，以便于阅读，但它是可复制/粘贴的。

Answer 2

$ echo "eh oh    37" | awk '{n=$NF+1; gsub(/[0-9]+$/,n) }1'
eh oh    38

或者

$ echo "eh oh    37" | awk '{n=$NF+1; gsub(/..$/,n) }1'
eh oh    38

Answer 3

类似的东西

number=`echo "eh oh 37" | grep -o '[0-9]*'`
sed 's/$number/`expr $number + 1`/'

Answer 4

怎么样：

$ echo "eh oh   37" | awk -F'[ \t]' '{$NF = $NF - 1;} 1'
eh oh   36

Answer 5

该解决方案不会保留小数位数，因此如果数字是 10，那么结果是 9，即使有人想要 09。

我没有编写尽可能短的代码，它应该保持可读

这里我构造了 printf使用 RLENGTH 的模式，使其变为 %02d （2 是匹配模式的长度）

$ echo "eh oh    10      aaa     22    bb" |
    awk '{n = substr($0, match($0, /[0-9]+/), RLENGTH)-1 ; 
          nn=sprintf("%0" RLENGTH "d", n)
          sub(/[0-9]+/, nn);
          print 
         }'
eh oh    09      aaa     22    bb