TCL tDom 空 XML 标签

Question

我使用 tDom 循环一些 XML 并提取每个元素的 text()。

    set xml {
<systems>
 <object>
  <type>Hardware</type>
  <name>Server Name</name>
  <attributes>
   <vendor></vendor>
  </attributes>
 </object>
 <object>
  <type>Hardware</type>
  <name>Server Two Name</name>
  <attributes>
   <vendor></vendor>
  </attributes>
 </object>
</systems>
};

    set doc  [dom parse $xml]
    set root [$doc documentElement]

    set nodeList [$root selectNodes /systems/object]

    foreach node $nodeList {

     set nType  [$node selectNodes type/text()]
     set nName  [$node selectNodes name/text()]
     set nVendor [$node selectNodes attributes/vendor/text()]

     # Etc...
     puts "Type: " 
     puts [$nType data] 

     # Etc ..

     puts [$nVendor data]
    }

但是，当它尝试打印出空的供应商时，它会显示错误命令名称“无效”。我如何忽略这一点并将 $nVendor 设置为空字符串？

Answer 1

节点的 selectNodes 方法返回与您的模式匹配的节点列表。当您直接使用结果作为命令时，

set nName  [$node selectNodes name/text()]
puts [$nType data] 

您真正做的是利用 1 个项目 的列表（name 项目的数量） 是相同的事实作为一件物品。当没有匹配的节点时，您会返回一个空列表

set nVendor [$node selectNodes attributes/vendor/text()]  ;# -> {}

，并且当您调用该列表时，它会抛出错误，因为您正在调用名称为 {} 的命令。

set nVendor [$node selectNodes attributes/vendor/text()]  ;# -> {}
puts [$nVendor data]  ;# -> winds up calling
{} data

正如 Hai Vu 所指出的，您可以通过对照 "" 检查结果来测试是否有结果。一种“更正确”的方法可能是根据空列表进行检查

set nVendor [$node selectNodes attributes/vendor/text()]
if {[llength $nVendor] == 1} {
    puts [$nVendor data]
}

，或者更完整（如果您不确定输入的 XML）

set nVendor [$node selectNodes attributes/vendor/text()]
switch -exact -- [llength $nVendor] {
    0 { 
        # no nVendor, do nothing
    }
    1 {
        # 1 vendor, print it
        puts [$nVendor data]
    }
    default {
        # weird, we got more than one vendor node... throw an error
        error "More than one vendor node"
    }
}

Answer 2

您可以检查 $nVendor 是否为空节点：

if {$nVendor != ""} {
    puts [$nVendor data]
}