AWK If/Else 条件问题

Question

我有一个看起来像这样的数据：

foo foo      scaffold_7      1 4845 6422 4845
bar bar      scaffold_7      -1 14689 16310 16310

我想做的是处理上面的行 我只想打印第 1,2,3,7 列以及第 7 列之后的一列。 但在打印第 7 栏以后有条件。

下面是我的 awk 脚本：

awk '{ 
        if ($4=="+") { {end=$6-$5}{print $1 "\t" $2 "\t" $3 "\t" $4 "\t" $7 "\t" end+$7} } 
        else 
            {end=$6-$5}{print $1 "\t" $2 "\t" $3 "\t" $4 "\t" $7-end "\t" $7} 
    }'  

但为什么它没有达到这样的预期结果呢？

foo foo    scaffold_7      1       4845    6422
bar bar   scaffold_7      -1      14689   16310

请注意，算术运算（例如$7-end 或end+$7）是必须的。所以我们不能只交换列 来自输入文件。此外，该 AWK 将位于 bash 脚本内。

Answer 1

尝试：

awk 'BEGIN {OFS = "\t"} { 
    end = $6 - $5
    if ($4 >= 0) {
        print $1, $2, $3, $4, $7, end + $7
    } else {
        print $1, $2, $3, $4, $7 - end, $7
    }
}'

我从未在大括号内使用过大括号，并且更喜欢使用分号分隔符来实现此目的。我非常确定在您的示例中，else 子句仅绑定到 {end=$6-$5}，而不是绑定到两个大括号条目。在这种情况下，{print $1 "\t" $2 "\t" $3 "\t" $4 "\t" $7-end "\t" $7} 将为所有执行行。

Answer 2

awk '{end=$6-$5}
$4>0{ $0=$1 "\t" $2 "\t" $3 "\t" $4 "\t" $7 "\t" end+$7 }
$4<=0{$0=$1 "\t" $2 "\t" $3 "\t" $4 "\t" $7-end "\t" $7 }1'  file

Answer 3

echo 'foo foo      scaffold_7      1 4845 6422 4845
bar bar      scaffold_7      -1 14689 16310 16310' | \
awk -v OFS='\t' '{
    print( \
        $1, $2, $3, $4, 
        ( \
            $4>0 ? $7 OFS ($6-$5) + $7 : $7 - ($6-$5) OFS $7 \
        ) \
    )
}'

foo     foo     scaffold_7      1       4845    6422
bar     bar     scaffold_7      -1      14689   16310

Answer 4

或者将其压缩为一行而不重复 print 语句：

 jot -s ' ' 7 -532 098 | mawk '{ print; $4=-$4; print }' |

mawk '($5 =(__ = $6 - $5) * -!(_ = -(_ = +$4)<_) + \
      ($6 = $7) )^(OFS = "\t") + ($--NF += _*__)'

-532    -427    -322    -217    -112     -7    98
-532    -427    -322    -217      -7     98

-532    -427    -322     217    -112     -7    98
-532    -427    -322     217      98    203