是否有类似“如果不存在则创建序列...”之类的内容？在 Oracle SQL 中？

Question

对于使用 Oracle 8 DB 的应用程序，我提供了一个 SQL 脚本来设置触发器、序列等内容，这些内容可以复制并粘贴到 SQL*Plus 中。如果我尝试创建的序列已经存在，我希望脚本不会因错误而停止。对于触发器，可以使用“创建或替换触发器...”轻松完成此操作，但对于序列，这不起作用。我也尝试过“如果不存在mysequence，则创建序列...”，但它也没有。有其他选择吗？

或者，如果这是不可能的，有没有办法在没有SQL *的情况下执行“删除序列mysequence”如果 mysequence 不存在，还要中止脚本吗？

Answer 1

DECLARE
  v_dummy NUMBER;
BEGIN
  -- try to find sequence in data dictionary
  SELECT 1
  INTO v_dummy
  FROM user_sequences
  WHERE sequence_name = 'MY_SEQUENCE_NAME';

  -- if sequence found, do nothing
EXCEPTION
  WHEN no_data_found THEN
    -- sequence not found, create it
    EXECUTE IMMEDIATE 'create sequence my_sequence_name';
END;

Answer 2

如果您确定脚本将始终在 SQL*Plus 下运行，则可以使用指令将 CREATE SEQUENCE 语句括起来，以在出现错误时继续：

WHENEVER SQLERROR CONTINUE
-- create sequences here, ignoring errors
WHENEVER SQLERROR EXIT SQL.SQLCODE

请注意创建过程中是否存在其他错误（权限问题、语法失败等）序列语句将被忽略

Answer 3

我喜欢：

DECLARE
  C NUMBER;
BEGIN
  SELECT COUNT(*) INTO C
  FROM ALL_TRIGGERS
  WHERE OWNER = 'YOUROWNER'
  AND TRIGGER_NAME = 'YOURTRIGGER';

  IF (C = 0) THEN
    EXECUTE IMMEDIATE '
      CREATE TRIGGER "YOUROWNER"."YOURTRIGGER"
        blah blah blah your trigger blah blah
    ';
  END IF;
END;
/

Answer 4

您可以检查user_sequence表来查看正在创建的序列是否已经存在。

与davek的解决方案类似：
这个想法是，在创建任何序列之前，删除序列并创建它，所有这些都在动态 SQL 中，创建一个函数，并说当您需要创建 10 个序列时，让该函数照顾...

function crt_seq(p_seq_name varchar2)
return boolean
begin
   for i in (select 1 from user_sequence where sequence_name = upper(p_seq_name))
   loop
   ---- Already exists. You can drop and recreate or return false to error out
   execute immediate 'drop sequence '||p_seq_name;
   execute immediate 'create sequence '||p_seq_name||' start with 1 increment
                    by 1 nocache';
   end loop;
   return true;
exception
when others then
   return false;
end;

您可以参数化所有其他选项并有一个复杂的功能来为您创建序列。

Answer 5

DECLARE
  lsSeqName VARCHAR2(32 CHAR) := UPPER('MY_SEQUENCE_NAME');
  lnSeqCount NUMBER;
BEGIN
  -- try to find sequence in data dictionary
  SELECT count(1)
    INTO lnSeqCount
    FROM user_sequences
    WHERE UPPER(sequence_name) = lsSeqName;
  -- if sequence not found, create it
  IF lnSeqCount = 0 THEN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE ' || lsSeqName || ' START WITH 1 MINVALUE 1 MAXVALUE 1000000000000000 INCREMENT BY 1 NOCYCLE CACHE 20 NOORDER';
  END IF;
END;
/

或者

-- helper method
PROCEDURE createSeqIfNotExists (
  isSeqName VARCHAR2
) IS
  lnSeqCount NUMBER;
BEGIN
  -- try to find sequence in data dictionary
  SELECT count(1)
    INTO lnSeqCount
    FROM user_sequences
    WHERE UPPER(sequence_name) = UPPER(isSeqName);
  -- if sequence not found, create it
  IF lnSeqCount = 0 THEN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE ' || UPPER(isSeqName) || ' START WITH 1 MINVALUE 1 MAXVALUE 1000000000000000 INCREMENT BY 1 NOCYCLE CACHE 20 NOORDER';
  END IF;
END createSeqIfNotExists;

-- call method
BEGIN
  createSeqIfNotExists('MY_SEQUENCE_NAME');
END;
/