Perl OOP 中继承抽象方法时，找不到方法错误

Question

我有一个从超类调用方法的子类。超类中的方法使用在超类中定义为抽象（不是真正抽象）但在子类中实现的方法。

例如：

package BaseClass;

sub new
{

}
sub method1 {

    return someAbstractMethod();
}



sub someAbtsractMethod
{
     die "oops, this is an abstract method that should " . 
         "be implemented in a subclass" ;
}
1;

package SubClass;

sub new
{

}

sub someAbtsractMethod
{
     print "now we implement the asbtract method";
}
1;

现在，当我这样做时：

$sub = new SubClass();
$sub->method1();

...它调用抽象消息，并且我收到指定的错误消息。如果我从超类中去掉抽象方法，而只将实现留在子类中，它不会识别该方法，并且会出现“子例程抽象方法未找到”错误。

Answer 1

您尚未在父类和子类之间设置 IS_A 关系。

您可以按照 Ivan 的建议使用 base 编译指示来执行此操作，或者您可以操作@ISA数组。或者您可以使用 parent 编译指示。

@ISA：

package SubClass;
our @ISA = qw( BaseClass );

parent：

package SubClass;
use parent qw( BaseClass );

顺便说一句，不要使用有史以来的间接对象语法。要调用构造函数，请执行以下操作：

my $foo = SubClass->new();

另外，您似乎没有使用 strict 和 警告 编译指示。这样做。总是。

最后，如果一个文件中有多个包，则将每个包包含在一个块中会很有帮助。

查看 perlboot 和 perltoot，它们是 perldoc 中方便的 OOP 教程。

更新：

我刚刚注意到您的方法调用已损坏。您需要在每个方法中找到调用类或实例。

package BaseClass;

sub new { bless {}, shift; }  # horrible constructor - do not reuse.

sub abstract { die "The present situation is abstract"; }

sub method { my $self = shift; $self->abstract; }


package SubClass;

our @ISA = qw( BaseClass );

sub abstract { print "It's alive\n" );

在脚本中：

my $obj = SubClass->new;
$obj->method;

my $base = BaseClass->new;
$base->method;

一定要阅读我链接到的教程。他们会帮助你。

Answer 2

你的代码有一些问题，你需要告诉子类它的父类是什么。您可能还需要设置构造函数以传递给父类。里面还有一些拼写错误。

package BaseClass;

sub new {
    bless {} => shift;
}
sub method1 {
    my $self = shift;

    return $self->someAbstractMethod();
}


sub someAbstractMethod
{
     die "oops, this is an abstract method that should " . 
         "be implemented in a subclass";
}


package SubClass;
use base 'BaseClass';

sub new {
    shift->SUPER::new
}

sub someAbstractMethod
{
     print "now we implement the asbtract method\n";
}


package main;

my $obj = BaseClass->new;

eval {$obj->method1(); 1} or warn $@;

my $subobj = SubClass->new;

$subobj->method1();

Answer 3

您的根本问题是您根本没有使用方法调用。如果您

sub method1 {
  my $self = shift;
  $self->someAbstractMethod();
}

在基类中完成了操作（并且假设继承设置正确），那么一切都会正常。但是，当您编写 someAbstractMethod() 时，它不是方法调用，而是函数调用，因此它会在编译时立即解析，而不考虑多态性（对象的类型是什么）。

Answer 4

如果您刚刚开始使用 Perl OO，请不要忘记查看 Moose。另请参阅 Moose::Manual::Unsweetened 了解 Moose 的比较具有常规 Perl 5 OOP 风格。