使用 awk 将每个字符打印为自己的列？

Question

我需要重新组织一个大型 CSV 文件。第一列目前是 6 位数字，需要使用逗号作为字段分隔符进行拆分。

例如，我需要这个：

022250,10:50 AM,274,22,50
022255,11:55 AM,275,22,55

变成这样：

0,2,2,2,5,0,10:50 AM,274,22,50
0,2,2,2,5,5,11:55 AM,275,22,55

让我知道你的想法！

谢谢！

Answer 1

Perl 中的内容要短得多：

perl -F, -ane '$,=","; print split("",$F[0]), @F[1..$#F]' <file>

因为您不了解 Perl，所以快速解释一下。 -F, 表示输入字段分隔符是逗号（如 awk）。 -a 激活自动拆分（到数组 @F 中），-n 隐式地将代码包装在 while 中（>) { ... } 循环，逐行读取输入。 -e 指示下一个参数是要运行的脚本。 $, 是输出字段分隔符（它以这种方式获取循环的设置迭代，但是哦，好吧）。 split 的目的很明显，您可以看到数组是如何索引/切片的。 print，当像这样列出作为参数时，使用输出字段分隔符并打印其所有字段。

在 awk 中：

awk -F, '{n=split($1,a,""); for (i=1;i<=n;i++) {printf("%s,",a[i])}; for (i=2;i<NF;i++) {printf("%s,",$i)}; print $NF}' <file>

Answer 2

我认为这可能有效。如果第三个参数是空字符串，则 split 函数（至少在我正在运行的版本中）会将值拆分为单个字符。

  BEGIN{ FS="," }
  {
     n = split( $1, a, "" );
     for ( i = 1; i <= n; i++ )
        printf("%s,", a[i] );

     sep = "";
     for ( i = 2; i <= NF; i++ )
        {
        printf( "%s%s", sep, $i );
        sep = ",";
        }
     printf("\n");
  }

Answer 3

这是 awk 中的另一种方法

$ awk -F"," '{gsub(".",",&",$1);sub("^,","",$1)}1' OFS="," file
0,2,2,2,5,0,10:50 AM,274,22,50
0,2,2,2,5,5,11:55 AM,275,22,55

Answer 4

这是一个主题的变体。需要注意的一件事是它在不使用循环的情况下打印剩余的字段。另一个问题是，既然您无论如何都要循环第一个字段中的字符，为什么不使用 split() 的空分隔符功能（在某些版本的 AWK 中可能不存在）来执行此操作：

awk -F, 'BEGIN{OFS=","} {len=length($1); for (i=1;i<len; i++) {printf "%s,", substr($1,i,1)}; printf "%s", substr($1,len,1);$1=""; print $0}' filename

作为脚本：

BEGIN {FS = OFS = ","}
{
    len = length($1); 
    for (i=1; i<len; i++)
        {printf "%s,", substr($1, i, 1)}; 
    printf "%s", substr($1, len, 1)
    $1 = "";
    print $0
}