我如何引用 Perl 子例程？

Question

我在弄清楚如何引用外部模块文件中的子例程时遇到了一些麻烦。现在，我正在这样做：

External file

package settingsGeneral;    
sub printScreen {
    print $_[0];
}

Main

use settingsGeneral;    
my $printScreen = settingsGeneral::printScreen;
&$printScreen("test");

但这会导致错误： 使用“严格引用”时不能使用字符串（“1”）作为子例程引用

Answer 1

正如 perlmodlib 中所述，您的模块名称应该以大写字母开头：

Perl 非正式地为“pragma”模块保留小写模块名称，例如 integer 和 strict。其他模块通常以大写字母开头，并使用不带下划线的混合大小写（需要简短且可移植）。

调用另一个包中定义的子程序的一种方法是在调用它时完全限定该子程序的名称：

SettingsGeneral::printScreen "important message\n";

如果您想要的只是对 printScreen 的引用，请使用反斜杠运算符获取它

my $subref = \&SettingsGeneral::printScreen;

并使用一个调用它您

&$subref("one\n");
&{$subref}("two\n");
$subref->("three\n");

可以在当前包中创建一个 别名：

*printScreen = \&SettingsGeneral::printScreen;
printScreen("another urgent flash\n");

跳过括号 (必要的，因为当前包中的子在编译时未知）通过编写：

use subs 'printScreen';
*printScreen = \&SettingsGeneral::printScreen;
printScreen "the sky is falling!\n";

Exporter模块可以为您完成此保管工作：

SettingsGeneral.pm:

package SettingsGeneral;

use Exporter 'import';

our @EXPORT = qw/ printScreen /;

sub printScreen {
  print $_[0];
}

1;

ma​​in:

#! /usr/bin/perl

use warnings;
use strict;

use SettingsGeneral;

printScreen "foo!\n";