当我单击下一帧时如何停止播放电影 - FLASH CS4？

Question

我在带有观看按钮的电影中的 4 帧中有四个影片剪辑 (.f4v)。这些 f4v 已导入到具有下一个和上一个按钮的主电影容器中。但是，如果我播放电影然后点击下一帧，电影将继续在后台播放。我怎样才能购买这个？下面的代码显示了其中一个影片剪辑的动作脚本，然后显示了主影片中的动作脚本。我是一个闪存新手，所以感谢所有帮助。 非常感谢。

stop();

watch1_btn.addEventListener(MouseEvent.CLICK, playMovie1);

function playMovie1(event:MouseEvent):void
{
    movie1_mc.play();
}

// Button Listeners
next_btn.addEventListener(MouseEvent.CLICK, nextSection);
prev_btn.addEventListener(MouseEvent.CLICK, prevSection);

function nextSection(event:MouseEvent):void {

    var thisLabel:String = pages_mc.currentLabel; // gets current frame label as string
    var thisLabelNum:String = thisLabel.replace("sct", ""); // cuts the leading letters off of the number
    var curNumber:Number = Number(thisLabelNum); // converts that string number to a real number
    if (curNumber < 5){
        var nextNum:Number = curNumber + 1; // adds 1 to the number so we can go to next frame label
        pages_mc.gotoAndStop("sct" + nextNum); // This allows us to go to the next frame label
        }
}
///////////////////////////////////////////////////////////////////////////
function prevSection(event:MouseEvent):void {

    var thisLabel:String = pages_mc.currentLabel; // gets current frame label as string
    var thisLabelNum:String = thisLabel.replace("sct", ""); // cuts the leading letters off of the number
    var curNumber:Number = Number(thisLabelNum); // converts that string number to a real number
    var prevNum:Number = curNumber - 1; // subtracts 1 from the number so we can go to next frame label
    pages_mc.gotoAndStop("sct" + prevNum); // This allows us to go to the previous frame label

}

Answer 1

在 gotoAndStop() 函数之前，放入 movie1_mc.stop();命令，这将在更改帧之前停止剪辑。

只是在开发方面，如果您只更改视频，请考虑仅使用一帧并使用 addChild() 和 removeChild() 从舞台添加/删除视频。事情通常更容易控制整体绕过这样的框架，并且是一个很好的学习工具。

Answer 2

您有一些很好的逻辑可以在帧之间移动，但有很多是不必要的。使用 currentFrame。这可以帮助清理您的代码，因为您不再需要拆分字符串然后转换为数字。

function nextSection(event:MouseEvent):void {
// This allows us to go to the currentframe plus one's label in one line of code
        pages_mc.gotoAndStop("sct" + (pages_mc.currentFrame + 1)); 
}

function prevSection(event:MouseEvent):void {
// This allows us to go to the currentframe minus one's label in one line of code
    pages_mc.gotoAndStop("sct" + (pages_mc.currentFrame - 1)); 
}

这些函数将移动到上一帧和下一帧，但不具备您想要的所有功能（例如停在第 5 帧或第 1 帧（未包含在您的原始代码中））...我会让如果你想使用它们，你可以添加它。

但还有一种更简单的方法可以在帧之间切换。 AS3 具有 nextFrame() 和 prevFrame() 函数，它们的功能正如它们听起来的那样（分别前进到下一帧和后退到上一帧）。

function nextSection(event:MouseEvent):void {
// This allows us to go to the next frame if we aren't 
// already at frame 5
   if(pages_mc.currentFrame<5){
        pages_mc.nextFrame();
   }
}

function prevSection(event:MouseEvent):void {
// This allows us to go to the previous frame if we aren't 
// already at frame 1
   if(pages_mc.currentFrame>1){
        pages_mc.prevFrame();
   }
}

啊。太清爽了。简单、实用的代码。

---

现在，谈谈你的实际问题。

mc.stop();，（其中 mc 是实际影片剪辑的占位符）将“停止”影片剪辑。但“停止”并不是这里使用的最佳词。 AS3 中的 stop() 函数更像是一个暂停按钮，在调用该函数时将影片剪辑“暂停”在正在播放的帧处。

当您返回到任何“暂停”影片剪辑的帧时，根据您的代码，您将只能从暂停点开始播放它。

function nextSection(event:MouseEvent):void {
   if(pages_mc.currentFrame<5){

       //"pause" the movie clip (only if moving to another frame)
        movie1_mc.stop();

        pages_mc.nextFrame();
   }
}

function prevSection(event:MouseEvent):void {
   if(pages_mc.currentFrame>1){

       //"pause" the movie clip (only if moving to another frame)
        movie1_mc.stop();

        pages_mc.prevFrame();
   }
}

我建议使用 Flash 的一些内置功能来播放 .f4v/.flv 文件。查看 FLVPlayback，并查看 这个答案查看如何使用它的示例。

FLVPlayback 会将文件中的影片剪辑替换为对计算机（或服务器）上文件的引用，从而使 Flash 文件小得多。它还有自己的电影控件，因此暂停、停止、播放和其他操作都可以立即使用，无需侦听器事件。

玩得开心并尝试！

我希望这有帮助！