(partial apply str) 和 clojure 中的 apply-str ->

Question

如果我执行以下操作：

user=> (-> ["1" "2"] (partial apply str)) 
#<core$partial__5034$fn__5040 clojure.core$partial__5034$fn__5040@d4dd758>

...我会恢复部分功能。但是，如果我将它绑定到变量：

user=> (def apply-str (partial apply str))
#'user/apply-str
user=> (-> ["1" "2" "3"] apply-str)       
"123"

...代码将按我的预期工作。我认为它们是同一件事，但显然情况并非如此。有人可以解释为什么这对我来说吗？

Answer 1

->是一个宏，因此它不必遵循您在应用方面期望的规则。宏在评估表单之前转换源。尝试宏扩展形式：

user> (macroexpand '(-> ["1" "2"] (partial apply str)))
(partial ["1" "2"] apply str)

您想通过使用“->”来实现什么目的宏？

编辑：请注意：

user> ((partial apply str) ["1" "2"])
"12"

Answer 2

你根本不必这样做。

(->> ["1" "2" "3"] (apply str))

为什么不这样做呢？

Answer 3

第一个表达式 (-> ["1" "2"] (partial apply str)) 扩展为：

(partial ["1" "2"] apply str)< /code> 基本上意味着：

使用 Vars apply< 从 ["1" "2"] 创建一个函数（这也是一个函数，因为向量是索引键的函数！） /code> 和 str 已作为前两个参数提供。该函数被打印为奇怪的 # 字符串。
仅当调用此函数时，您才会收到 IllegalArgumentException，因为向量仅采用一个整数参数，而不是两个 Var 参数。

Answer 4

宏 -> 将 expr 作为第二个参数穿过表单。在您的情况下，最终扩展为：(partial ["1" "2"] apply str)，创建基于向量的 parital 函数。

但是您想要调用基于线程表达式上的 apply 和 str 的 parital 函数，因此需要：

(-> ["1" "2"] ((partial apply str)))

嗯：这段代码非常令人困惑，而且不是惯用的 Clojure。

Answer 5

-> 宏在第二个版本中的 apply-str 周围添加了括号，这就是宏扩展为最终调用您的函数的代码的原因。查看->的源代码，您可以看到：

(defmacro ->
  "Threads the expr through the forms. Inserts x as the
  second item in the first form, making a list of it if it is not a
  list already. If there are more forms, inserts the first form as the
  second item in second form, etc."
  ([x] x)
  ([x form] (if (seq? form)
              (with-meta `(~(first form) ~x ~@(next form)) (meta form))
              (list form x)))
  ([x form & more] `(-> (-> ~x ~form) ~@more)))

相关部分是当它处理两个参数时，x和form。如果 form 是一个 seq，则 x 将作为第二个参数插入到该列表中。否则，宏会将 form 和 x 放入列表本身。这样您就可以使用一个裸符号作为包含一个符号的列表的简写。

user> (macroexpand '(-> 123 (foo)))
(foo 123)
user> (macroexpand '(-> 123 foo))
(foo 123)