delphi中消息解码器的设计建议

Question

我想实现一个RPC模块。不同的请求被编码为 JSON 对象。它们将被解码，然后由请求处理程序处理。最后会返回相应的响应。演示代码如下：

type
  IRequestHandler = interface
    function Handle(const Request: TAaaRequest): TResponse;
    function Handle(const Request: TBbbRequest): TResponse;
  end;

  TDecoder = class
    class function Decode(const Json: TJsonObject; const RequestHandler: IRequestHandler): TResponse;
  end;

class function TDecoder.Decode(const Json: TJsonObject; const RequestHandler: IRequestHandler): TResponse;
var
  Method: string;
  Request: TObject;
begin
  Method := Json['method'].AsString;
  if (Method = TAaaRequest.ClassName) then
  begin
    Request := TAaaRequest.FromJSON(Json); // Casted as TObject
    if Request <> nil then
    begin
      Result := RequestHandler.Handle(TAaaRequest(Request));
      Request.Free;
    end;
  end
  else if (Method = TBbbRequest.ClassName) then
  begin
    Request := TBbbRequest.FromJSON(Json); // Casted as TObject
    if Request <> nil then
    begin
      Result := RequestHandler.Handle(TBbbRequest(Request));
      Request.Free;
    end;
  end
  else
    Result := CreateErrorResponse('Unknown method: ' + Json.ToString);
end;

从代码来看，不同请求类型的处理非常相似。如果我有 100 种不同的请求类型，我必须复制并粘贴上述代码块 100 次。这并不聪明。我正在寻找一种更好的方法来执行相同的逻辑。我的想象如下：

TDecoder = class
private
  FRequestTypes: TDictionary<string, TClassInfo>; // Does this work?
public
  constructor Create;
  destructor Destroy; override;
  function Decode(const Json: TJsonObject; const RequestHandler: IRequestHandler): TResponse;
end;

constructor TDecoder.Create;
begin
  FRequestTypes := TDictionary<string, TClassInfo>.Create;
  FRequestTypes.Add(TAaaRequest.ClassName, TAaaRequest); // Does this work?
  FRequestTypes.Add(TBbbRequest.ClassName, TBbbRequest); 
end;

destructor TDecoder.Destroy;
begin
  FRequestTypes.Free;
  inherited;
end;

function TDecoder.Decode(const Json: TJsonObject; const RequestHandler: IRequestHandler): TResponse;
var
  Method: string;
  Info: TClassInfo;
  Request: TObject;
begin
  Method := Json['method'].AsString;
  if FRequestTypes.ContainsKey(Method) then
  begin
    // An universal way
    Info := FRequestTypes[Method];
    Request := Info.FromJSON(Json); // Casted as TObject
    if Request <> nil then
    begin
      Result := RequestHandler.Handle(Info(Request)); // Casted to corresponding class type (e.g. TAaaRequest or TBbbRequest)
      Request.Free;
    end;
  end
  else
    Result := CreateErrorResponse('Unknown method: ' + Json.ToString);
end;

我不知道是否可以编写一种通用的方法来处理大量不同的请求类型。开发环境 Delphi 2010。

如有任何提示，我们将不胜感激。

Answer 1

你的第二次尝试非常接近。你只是缺少一些细节。

如果您使用了虚构类型 TClassInfo，则需要定义一个元类来表示您的请求类。我假设 TAaaRequest 和 TBbbRequest（以及其他 100 个请求类）都源自某个基类 TRequest。像这样定义 TRequestClass：

type
  TRequestClass = class of TRequest;

FromJSON 方法对每个类执行不同的操作，对吗？如果是这样的话，那么它应该是虚拟的。 （如果该方法在每个类中执行相同的操作，那么它就不必是虚拟的，尽管其他人可能会告诉您。）您不必对方法的结果进行类型转换构造函数；只需将 Info 声明为 TRequest 而不是 TObject。

您需要进行的最大更改是您的 IRequestHandler 接口。由于每个对象都是一个 TRequest，因此在没有巨大的 if-else 梯子的情况下分派到正确的接口方法将是笨拙的检查每个可能的类别。

相反，再次使用虚拟调度。为每个 TRequest 对象提供一个虚拟 Handle 方法，因此类声明将如下所示：

type
  TRequest = class
  public
    constructor FromJSON(const json: string);
    function Handle: TResponse; virtual; abstract;
  end;

为每个后代实现 Handle ，然后就完成了。最终，IRequestHandler 接口可能会消失。您已经将处理能力写入每个请求类中。您不需要一个类来表示请求，而另一个类来处理它。

如果您想要一个单独的处理类，那么您可以使用已有的处理类，您将有一个很大的条件来决定要调用哪个 IRequestHandler 方法，或者您有很多请求处理程序对象都实现相同的接口，您可以像决定创建哪个请求类一样决定创建哪个请求处理程序对象。然后将请求对象交给请求处理程序对象并让它们一起工作。

例如，定义您的处理程序接口：

type
  IRequestHandler = interface
    function Handle(request: TRequest): TResponse;
  end;

像注册请求一样注册处理程序：

// Use the same names as the requests, but a different dictionary
FRequestHandlers.Add(TAaaRequest.ClassName, TAaaHandler);
FRequestHandlers.Add(TBbbRequest.ClassName, TBbbHandler);

像处理请求一样实例化处理程序：

HandlerType := FRequestHandlers[Method];
HandlerObject := HandlerType.Create;
if not Supports(HandlerObject, IRequestHandler, Handler) then
  exit;

然后将请求传递给处理程序：

Result := Handler.Handle(Request);