如何判断 Log4perl 在运行期间是否发出任何警告？

Question

我一直在许多脚本中广泛使用 Log4perl 。我想扩充这些脚本，以便在记录了任何 WARN 或 ERROR 消息时设置错误代码。根据现有文档，我找不到任何明显的方法来做到这一点。

我想避免对现有脚本进行强力重写，以添加对每个 WARN 或 ERROR 日志消息的检查；如果可能的话，我更愿意在脚本退出之前处理它，就像这样的伪代码：

if $log->has_warnings_or_errors then
  exit 1
else
  exit 0

有没有简单的方法来调用 Log4Perl 来确定当前记录器是否有某些级别的问题消息？

Answer 1

使用 appender。

MyCounter.pm:

package MyCounter;

use warnings;
use strict;

use Log::Log4perl::Level;

sub new {
  my($class,%arg) = @_;
  bless {} => $class;
}

sub log {
  my($self,%arg) = @_;
  ++$self->{ $arg{log4p_level} };
}

sub howmany {
  my($self,@which) = @_;
  my $total = 0;
  $total += ($self->{$_} || 0) for @which;
  $total;
}

1;

myprog:

#! /usr/bin/perl

use warnings;
use strict;

use Log::Log4perl;

my $conf = q(
  log4perl.category.MyLogger = INFO, Screen

  log4perl.appender.Screen = Log::Log4perl::Appender::Screen
  log4perl.appender.Screen.layout = Log::Log4perl::Layout::SimpleLayout
);

Log::Log4perl->init(\$conf);

my $l = Log::Log4perl->get_logger("MyLogger");

my $counter = Log::Log4perl::Appender->new("MyCounter");
$l->add_appender($counter);

$l->warn("warning");
$l->info("info");
$l->error("incorrect");
$l->fatal("really bad, man");

print $counter->howmany(qw/ WARN ERROR FATAL /), "\n";

exit ($counter->howmany(qw/ WARN ERROR FATAL /) ? 1 : 0);

输出：

$ ./myprog 
WARN - warning
INFO - info
ERROR - incorrect
FATAL - really bad, man
3
$ echo $?
1

注释掉 ...->warn、...->error 和 ...->fatal 行来获取

$ ./myprog 
INFO - info
0
$ echo $?
0

Answer 2

您可以使用 包装器 并编写自定义 fatal、error 和 warn 方法，用于递增计数器以及返回该计数器值的访问器。